reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem
  (x*y)*z == x*(y*z)
proof
  defpred P[Ordinal] means
  for x,y,z be Surreal st born x (+) born y (+) born z c= $1 holds
  (x*y)*z == x*(y*z);
  A1: for D be Ordinal st for C be Ordinal st C in D holds P[C] holds P[D]
  proof
    let D be Ordinal such that A2: for C be Ordinal st C in D holds P[C];
    let x,y,z such that A3:born x (+) born y (+) born z c= D;
    set xy=x*y, yz=y*z;
    A4: xy = [comp(L_x,x,y,L_y) \/ comp(R_x,x,y,R_y),
    comp(L_x,x,y,R_y) \/ comp(R_x,x,y,L_y)] by Th50;
    A5: yz = [comp(L_y,y,z,L_z) \/ comp(R_y,y,z,R_z),
    comp(L_y,y,z,R_z) \/ comp(R_y,y,z,L_z)] by Th50;
    A6:x*yz = [comp(L_x,x,yz,L_yz) \/ comp(R_x,x,yz,R_yz),
    comp(L_x,x,yz,R_yz) \/ comp(R_x,x,yz,L_yz)] by Th50;
    A7:xy * z = [comp(L_xy,xy,z,L_z) \/ comp(R_xy,xy,z,R_z),
    comp(L_xy,xy,z,R_z) \/ comp(R_xy,xy,z,L_z)] by Th50;
    A8: for X,Y,Z be surreal-membered set st
    (X=L_x or X=R_x) & (Y=L_y or Y=R_y) & (Z=L_z or Z=R_z)
    holds comp(X,x,yz,comp(Y,y,z,Z)) <==> comp(comp(X,x,y,Y),xy,z,Z)
    proof
      let X,Y,Z be surreal-membered set such that
      A9: (X=L_x or X=R_x) & (Y=L_y or Y=R_y) & (Z=L_z or Z=R_z);
      for o be Surreal st o in comp(X,x,yz,comp(Y,y,z,Z))
      ex b be Surreal st b in comp(comp(X,x,y,Y),xy,z,Z) & o==b
      proof
        let o be Surreal;
        assume o in comp(X,x,yz,comp(Y,y,z,Z));
        then consider x1,yz1 be Surreal such that
        A10: o = x1*yz + x*yz1 - x1*yz1 & x1 in X & yz1 in comp(Y,y,z,Z)
        by Def15;
        consider y1,z1 be Surreal such that
        A11: yz1  = y1*z + y*z1 - y1*z1 & y1 in Y & z1 in Z by A10,Def15;
        A12:x*(y1*z + y*z1) == x*(y1*z) + x*(y*z1) by Th67;
        A13:x*(y1*z + y*z1) + (x * (- y1*z1)) ==
        (x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)) by A12,Th43;
        x*((y1*z + y*z1) + (- y1*z1)) == x*(y1*z + y*z1) + (x * (- y1*z1))
        by Th67;
        then A14:x*((y1*z + y*z1) + (- y1*z1)) ==
        (x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)) by A13,SURREALO:4;
        A15:x1*(y1*z + y*z1) == x1*(y1*z) + x1*(y*z1) by Th67;
        A16:x1*(y1*z + y*z1) + (x1 * (- y1*z1)) ==
        (x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)) by A15,Th43;
        x1*((y1*z + y*z1) + (- y1*z1)) == x1*(y1*z + y*z1) + (x1 * (- y1*z1))
        by Th67;
        then x1*((y1*z + y*z1) + (- y1*z1)) ==
        (x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)) by A16,SURREALO:4;
        then A17: -( x1*((y1*z + y*z1) + (- y1*z1))) ==
        - ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1))) by Th10;
        x1*yz + x*(y1*z + y*z1 + - y1*z1) ==
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)))
        by A14,Th43;
        then A18: o == x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)))
        +- ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1))) by A10,A11,A17,Th43;
        A19: R_x<> {x} <> L_x & R_y<>{y} <> L_y & R_z<>{z} <> L_z
        by SURREALO:2;
        A20:x in {x} & y in {y} & z in {z} by TARSKI:def 1;
        then born x1 (+) born y (+) born z in born x (+) born y (+) born z
        by A10,A9,A19,Lm7;
        then A21: x1*y*z == x1*(y*z) by A2,A3;
        born x (+) born y1 (+) born z in born x (+) born y (+) born z
        by A11,A9,A19,A20,Lm7;
        then A22: x*y1*z == x*(y1*z) by A2,A3;
        born x (+) born y (+) born z1 in born x (+) born y (+) born z
        by A11,A9,A19,A20,Lm7;
        then
        A23: x*y*z1 == x*(y*z1) by A2,A3;
        born x (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A11,A9,A19,A20,Lm7;
        then
        A24: x*y1*z1 == x*(y1*z1) by A2,A3;
        born x1 (+) born y (+) born z1 in born x (+) born y (+) born z
        by A10,A11,A9,A19,A20,Lm7;
        then
        A25: x1*y*z1 == x1*(y*z1) by A2,A3;
        born x1 (+) born y1 (+) born z in born x (+) born y (+) born z
        by A10,A11,A9,A19,A20,Lm7;
        then
        A26: x1*y1*z == x1*(y1*z) by A2,A3;
        born x1 (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A10,A11,A9,A19,Lm7;
        then
        A27: x1*y1*z1 == x1*(y1*z1) by A2,A3;
        A28: x1*yz +x*(y1*z) == x1*y*z + x*y1*z by A21,A22,Th43;
        (x * (- y1*z1)) = - (x * (y1*z1)) by Th58;
        then A29: (x * (- y1*z1)) == - (x * y1*z1) by A24,Th10;
        (- x1*y1)*z = - ((x1*y1)*z) == - (x1*(y1*z)) by A26,Th58,Th10;
        then  (x1*yz +x*(y1*z)) + (- (x1*(y1*z))) ==
        x1*y*z + x*y1*z + (- x1*y1)*z by A28,Th43;
        then  (x1*yz +x*(y1*z)) + (- (x1*(y1*z)))+ x*(y*z1)   ==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 by Th43,A23;
        then A30: (x1*yz +x*(y1*z)) + (-(x1*(y1*z)))+ x*(y*z1) + (x *(-y1*z1))
        == x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +-( x*y1*z1)
        by Th43,A29;
        x1 * (- y1*z1) = - (x1 * (y1*z1)) by Th58;
        then x1 * (- y1*z1) == - (x1 * y1*z1) by Th10,A27;
        then x1 * (- y1*z1) == (-x1 * y1)*z1 by Th58;
        then  (x1*(y*z1) + (x1 * (- y1*z1))) == (x1*y*z1 + (- x1*y1)*z1)
        by Th43,A25;
        then A31: -(x1*(y*z1) + (x1 * (- y1*z1))) == -(x1*y*z1+ (- x1*y1)*z1)
        by Th10;
        A32: (x1*yz +x*(y1*z)) + (- (x1*(y1*z))) + x*(y*z1) +
        (x * (- y1*z1)) + - ((x1*(y*z1) + (x1 * (- y1*z1))))==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +
        -( x*y1*z1)     + -(x1*y*z1+ (- x1*y1)*z1)
        by A30,A31,Th43;
        (x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)) =
        x1*(y1*z) + (x1*(y*z1) + (x1 * (- y1*z1))) by Th37;
        then A33: - ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)))  =
        - (x1*(y1*z)) + - ((x1*(y*z1) + (x1 * (- y1*z1))))
        by Th40;
        x1*y*z1 + x*y1*z1 +(- x1*y1)*z1 =
        x*y1*z1 + (x1*y*z1+ (- x1*y1)*z1) by Th37;
        then A34:-(x1*y*z1 + x*y1*z1 +   (- x1*y1)*z1) =
        -( x*y1*z1) + -(x1*y*z1+ (- x1*y1)*z1) by Th40;
        A35: x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) + (- (x1*(y1*z)))
        = x1*yz +(x*(y1*z) + (x*(y*z1) + (x * (- y1*z1)))) + (- (x1*(y1*z)))
        by Th37
        .= (x1*yz +x*(y1*z)) + (x*(y*z1) + (x * (- y1*z1))) + (- (x1*(y1*z)))
        by Th37
        .= (x1*yz +x*(y1*z)) + ((x*(y*z1) + (x * (- y1*z1))) + (- (x1*(y1*z))))
        by Th37
        .= (x1*yz +x*(y1*z)) + ((- (x1*(y1*z))) + x*(y*z1) + (x * (- y1*z1)))
        by Th37
        .= (x1*yz +x*(y1*z)) + ((- (x1*(y1*z))) + x*(y*z1)) + (x * (- y1*z1))
        by Th37
        .= (x1*yz +x*(y1*z)) + (- (x1*(y1*z))) + x*(y*z1) + (x * (- y1*z1))
        by Th37;
        A36: x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) +
        (-(x1*(y1*z)) + - ((x1*(y*z1) + (x1 * (- y1*z1)))))
        =
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) + -(x1*(y1*z))
        + - ((x1*(y*z1) + (x1 * (- y1*z1)))) by Th37;
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)))
        +- ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)))==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +
        (-(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1)) by A32,A35,A33,A34,A36,Th37;
        then A37: o == x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +
        (-(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1)) by A18,SURREALO:4;
        (x1*y + x*y1)*z == x1*y*z + x*y1*z by Th67;
        then A38:(x1*y + x*y1)*z + (- x1*y1)*z == x1*y*z + x*y1*z + (- x1*y1)*z
        by Th43;
        (x1*y + x*y1 + - x1*y1)*z == (x1*y + x*y1)*z + (- x1*y1)*z by Th67;
        then A39: (x1*y + x*y1 + - x1*y1)*z == x1*y*z + x*y1*z + (- x1*y1)*z
        by A38,SURREALO:4;
        (x1*y + x*y1)*z1 == x1*y*z1 + x*y1*z1 by Th67;
        then A40:(x1*y + x*y1)*z1 + (- x1*y1)*z1 ==
        x1*y*z1 + x*y1*z1 + (- x1*y1)*z1  by Th43;
        (x1*y + x*y1 + - x1*y1)*z1 == (x1*y + x*y1)*z1 + (- x1*y1)*z1 by Th67;
        then  (x1*y + x*y1 + - x1*y1)*z1 == x1*y*z1 + x*y1*z1 + (- x1*y1)*z1
        by A40,SURREALO:4;
        then A41: - ((x1*y + x*y1 + - x1*y1)*z1) ==
        -(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1) by Th10;
        set xy1= x1*y + x*y1 - x1*y1;
        xy1*z + xy*z1 == x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 by A39,Th43;
        then xy1*z + xy*z1 +- xy1*z1 ==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +
        (-(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1)) by Th43,A41;
        then A42:o == xy1*z + xy*z1 - xy1*z1 by A37,SURREALO:4;
        xy1 in comp(X,x,y,Y) by Def15,A10,A11;
        then xy1*z + xy*z1 - xy1*z1 in comp(comp(X,x,y,Y),xy,z,Z)by Def15,A11;
        hence thesis by A42;
      end;
      hence comp(X,x,yz,comp(Y,y,z,Z)) <=_ comp(comp(X,x,y,Y),xy,z,Z) by Th61;
      for o be Surreal st o in comp(comp(X,x,y,Y),xy,z,Z)
      ex b be Surreal st b in comp(X,x,yz,comp(Y,y,z,Z)) & o==b
      proof
        let o be Surreal;assume  o in comp(comp(X,x,y,Y),xy,z,Z);
        then consider xy1,z1 be Surreal such that
        A43: o = xy1*z + xy*z1 - xy1*z1 & xy1 in comp(X,x,y,Y) & z1 in Z
        by Def15;
        consider x1,y1 be Surreal such that
        A44: xy1  = x1*y + x*y1 - x1*y1 & x1 in X & y1 in Y by A43,Def15;
        set yz1 = y1*z + y*z1 - y1*z1;
        A45:x*(y1*z + y*z1) == x*(y1*z) + x*(y*z1) by Th67;
        A46:x*(y1*z + y*z1) + (x * (- y1*z1)) ==
        (x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)) by A45,Th43;
        x*((y1*z + y*z1) + (- y1*z1)) ==
        x*(y1*z + y*z1) + (x * (- y1*z1)) by Th67;
        then A47:x*((y1*z + y*z1) + (- y1*z1)) ==
        (x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)) by A46,SURREALO:4;
        A48:x1*(y1*z + y*z1) == x1*(y1*z) + x1*(y*z1) by Th67;
        A49:x1*(y1*z + y*z1) + (x1 * (- y1*z1)) ==
        (x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)) by A48,Th43;
        x1*((y1*z + y*z1) + (- y1*z1)) == x1*(y1*z + y*z1) + (x1 * (- y1*z1))
        by Th67;
        then x1*((y1*z + y*z1) + (- y1*z1)) ==
        (x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)) by A49,SURREALO:4;
        then A50: -( x1*((y1*z + y*z1) + (- y1*z1))) ==
        - ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1))) by Th10;
        x1*yz + x*(y1*z + y*z1 + - y1*z1) ==
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) by A47,Th43;
        then A51: x1*yz + x*yz1 + - x1*yz1 ==
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1)))
        +- ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1))) by A50,Th43;
        A52: R_x<> {x} <> L_x & R_y<>{y} <> L_y & R_z<>{z} <> L_z
        by SURREALO:2;
        A53:x in {x} & y in {y} & z in {z} by TARSKI:def 1;
        born x1 (+) born y (+) born z in born x (+) born y (+) born z
        by A44,A9,A52,A53,Lm7;
        then A54: x1*y*z == x1*(y*z) by A2,A3;
        born x (+) born y1 (+) born z in born x (+) born y (+) born z
        by A44,A9,A52,A53,Lm7;
        then A55: x*y1*z == x*(y1*z) by A2,A3;
        born x (+) born y (+) born z1 in born x (+) born y (+) born z
        by A43,A9,A52,A53,Lm7;
        then A56: x*y*z1 == x*(y*z1) by A2,A3;
        born x (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A43,A44,A9,A52,A53,Lm7;
        then
        A57: x*y1*z1 == x*(y1*z1) by A2,A3;
        born x1 (+) born y (+) born z1 in born x (+) born y (+) born z
        by A43,A44,A9,A52,A53,Lm7;
        then
        A58: x1*y*z1 == x1*(y*z1) by A2,A3;
        born x1 (+) born y1 (+) born z in born x (+) born y (+) born z
        by A44,A9,A52,A53,Lm7;
        then
        A59: x1*y1*z == x1*(y1*z) by A2,A3;
        born x1 (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A43,A44,A9,A52,Lm7;
        then
        A60: x1*y1*z1 == x1*(y1*z1) by A2,A3;
        A61: x1*yz +x*(y1*z) == x1*y*z + x*y1*z by A54,A55,Th43;
        (x * (- y1*z1)) = - (x * (y1*z1)) by Th58;
        then A62: (x * (- y1*z1)) == - (x * y1*z1) by A57,Th10;
        (- x1*y1)*z = - ((x1*y1)*z) == - (x1*(y1*z)) by A59,Th58,Th10;
        then (x1*yz +x*(y1*z)) + (- (x1*(y1*z))) ==
        x1*y*z + x*y1*z + (- x1*y1)*z by A61,Th43;
        then (x1*yz +x*(y1*z)) + (- (x1*(y1*z)))+ x*(y*z1)   ==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 by Th43,A56;
        then A63: (x1*yz +x*(y1*z)) + (- (x1*(y1*z)))+ x*(y*z1) +
        (x * (- y1*z1)) == x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +-( x*y1*z1)
        by Th43,A62;
        x1 * (- y1*z1) = - (x1 * (y1*z1)) by Th58;
        then x1 * (- y1*z1) == - (x1 * y1*z1) by Th10,A60;
        then x1 * (- y1*z1) == (-x1 * y1)*z1 by Th58;
        then  (x1*(y*z1) + (x1 * (- y1*z1))) == (x1*y*z1 + (- x1*y1)*z1)
        by Th43,A58;
        then A64: -(x1*(y*z1) + (x1 * (- y1*z1))) == -(x1*y*z1+ (- x1*y1)*z1)
        by Th10;
        (x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)) =
        x1*(y1*z) + (x1*(y*z1) + (x1 * (- y1*z1))) by Th37;
        then A65: - ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)))  =
        - (x1*(y1*z)) + - ((x1*(y*z1) + (x1 * (- y1*z1)))) by Th40;
        x1*y*z1 + x*y1*z1 + (- x1*y1)*z1 =
        x*y1*z1 + (x1*y*z1+ (- x1*y1)*z1) by Th37;
        then A66:-(x1*y*z1 + x*y1*z1 +   (- x1*y1)*z1) =
        -( x*y1*z1) + -(x1*y*z1+ (- x1*y1)*z1) by Th40;
        A67: x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) + (- (x1*(y1*z)))
        = x1*yz +(x*(y1*z) + (x*(y*z1) + (x * (- y1*z1)))) + (- (x1*(y1*z)))
        by Th37
        .= (x1*yz +x*(y1*z)) + (x*(y*z1) + (x * (- y1*z1))) + (- (x1*(y1*z)))
        by Th37
        .= (x1*yz +x*(y1*z)) + ((x*(y*z1) + (x * (- y1*z1))) + (- (x1*(y1*z))))
        by Th37
        .= (x1*yz +x*(y1*z)) + ((- (x1*(y1*z))) + x*(y*z1) + (x * (- y1*z1)))
        by Th37
        .= (x1*yz +x*(y1*z)) + ((- (x1*(y1*z))) + x*(y*z1)) + (x * (- y1*z1))
        by Th37
        .= (x1*yz +x*(y1*z)) + (- (x1*(y1*z))) + x*(y*z1) + (x * (- y1*z1))
        by Th37;
        A68: x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) + (-(x1*(y1*z)) +
        - ((x1*(y*z1) + (x1 * (- y1*z1))))) =
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) + -(x1*(y1*z))+
        - ((x1*(y*z1) + (x1 * (- y1*z1)))) by Th37;
        x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) + -(x1*(y1*z))+
        - ((x1*(y*z1) + (x1 * (- y1*z1))))==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +-( x*y1*z1)+
        -(x1*y*z1+ (- x1*y1)*z1) by A63,A64,Th43,A67;
        then x1*yz +((x*(y1*z) + x*(y*z1)) + (x * (- y1*z1))) +-
        ((x1*(y1*z) + x1*(y*z1)) + (x1 * (- y1*z1)))==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 + (-(x1*y*z1 + x*y1*z1
        + (- x1*y1)*z1)) by A65,A66,A68,Th37;
        then A69: x1*yz + x*yz1 + - x1*yz1 ==
        x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1
        + (-(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1)) by A51,SURREALO:4;
        (x1*y + x*y1)*z == x1*y*z + x*y1*z by Th67;
        then A70:(x1*y + x*y1)*z + (- x1*y1)*z == x1*y*z + x*y1*z + (- x1*y1)*z
        by Th43;
        (x1*y + x*y1 + - x1*y1)*z == (x1*y + x*y1)*z + (- x1*y1)*z by Th67;
        then A71: (x1*y + x*y1 + - x1*y1)*z == x1*y*z + x*y1*z + (- x1*y1)*z
        by A70,SURREALO:4;
        (x1*y + x*y1)*z1 == x1*y*z1 + x*y1*z1 by Th67;
        then A72:(x1*y + x*y1)*z1 + (- x1*y1)*z1 ==
        x1*y*z1 + x*y1*z1 + (- x1*y1)*z1 by Th43;
        (x1*y + x*y1 + - x1*y1)*z1 == (x1*y + x*y1)*z1 + (- x1*y1)*z1 by Th67;
        then (x1*y + x*y1 + - x1*y1)*z1 == x1*y*z1 + x*y1*z1 + (- x1*y1)*z1
        by A72,SURREALO:4;
        then A73: - ((x1*y + x*y1 + - x1*y1)*z1) ==
        -(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1) by Th10;
        xy1*z + xy*z1 == x1*y*z + x*y1*z + (-x1*y1)*z + xy*z1 by A44,A71,Th43;
        then xy1*z + xy*z1 +- xy1*z1 == x1*y*z + x*y1*z + (- x1*y1)*z + xy*z1 +
        (-(x1*y*z1 + x*y1*z1 + (- x1*y1)*z1)) by A44,Th43,A73;
        then A74:o == x1*yz + x*yz1 - x1*yz1 by A43,A69,SURREALO:4;
        yz1 in comp(Y,y,z,Z) by Def15,A43,A44;
        then x1*yz + x*yz1 - x1*yz1 in comp(X,x,yz,comp(Y,y,z,Z))
        by Def15,A44;
        hence thesis by A74;
      end;
      hence thesis by Th61;
    end;
    A75:comp(L_xy,xy,z,L_z)
    = comp(comp(L_x,x,y,L_y),xy,z,L_z)\/comp(comp(R_x,x,y,R_y),xy,z,L_z)
    by A4,Th68;
    A76: comp(R_xy,xy,z,R_z) =
    comp(comp(L_x,x,y,R_y),xy,z,R_z) \/ comp(comp(R_x,x,y,L_y),xy,z,R_z)
    by A4,Th68;
    A77: comp(L_x,x,yz,L_yz)
    = comp(L_x,x,yz,comp(L_y,y,z,L_z)) \/ comp(L_x,x,yz,comp(R_y,y,z,R_z))
    by A5,Th60;
    A78: comp(R_x,x,yz,R_yz)
    = comp(R_x,x,yz,comp(L_y,y,z,R_z)) \/ comp(R_x,x,yz,comp(R_y,y,z,L_z))
    by A5,Th60;
    A79:comp(comp(L_x,x,y,L_y),xy,z,L_z) <==> comp(L_x,x,yz,comp(L_y,y,z,L_z))
    by A8;
    A80:comp(comp(R_x,x,y,R_y),xy,z,L_z) <==> comp(R_x,x,yz,comp(R_y,y,z,L_z))
    by A8;
    A81:comp(comp(L_x,x,y,R_y),xy,z,R_z) <==> comp(L_x,x,yz,comp(R_y,y,z,R_z))
    by A8;
    A82:comp(comp(R_x,x,y,L_y),xy,z,R_z) <==> comp(R_x,x,yz,comp(L_y,y,z,R_z))
    by A8;
    A83:comp(L_xy,xy,z,L_z) <==> comp(L_x,x,yz,comp(L_y,y,z,L_z))
    \/ comp(R_x,x,yz,comp(R_y,y,z,L_z))
    by A75,A79,A80,SURREALO:31;
    A84: comp(R_xy,xy,z,R_z) <==> comp(L_x,x,yz,comp(R_y,y,z,R_z))
    \/ comp(R_x,x,yz,comp(L_y,y,z,R_z))
    by A76,A81,A82,SURREALO:31;
    A85: (comp(L_x,x,yz,comp(L_y,y,z,L_z))\/ comp(R_x,x,yz,comp(R_y,y,z,L_z)))
    \/ (comp(L_x,x,yz,comp(R_y,y,z,R_z))\/ comp(R_x,x,yz,comp(L_y,y,z,R_z)))
    = ((comp(L_x,x,yz,comp(L_y,y,z,L_z))\/ comp(R_x,x,yz,comp(R_y,y,z,L_z))) \/
    comp(L_x,x,yz,comp(R_y,y,z,R_z)) )\/ comp(R_x,x,yz,comp(L_y,y,z,R_z))
    by XBOOLE_1:4
    .= ((comp(L_x,x,yz,comp(L_y,y,z,L_z))\/ comp(L_x,x,yz,comp(R_y,y,z,R_z)))\/
    comp(R_x,x,yz,comp(R_y,y,z,L_z))) \/ comp(R_x,x,yz,comp(L_y,y,z,R_z))
    by XBOOLE_1:4
    .= (comp(L_x,x,yz,comp(L_y,y,z,L_z)) \/ comp(L_x,x,yz,comp(R_y,y,z,R_z)))\/
    (comp(R_x,x,yz,comp(L_y,y,z,R_z)) \/ comp(R_x,x,yz,comp(R_y,y,z,L_z)))
    by XBOOLE_1:4;
    A86: L_(xy * z) <==> L_(x*yz) by A6,A85,A77,A78,A84,A7,A83,
    SURREALO:31;
    A87: comp(L_x,x,yz,R_yz)=
    comp(L_x,x,yz,comp(L_y,y,z,R_z))\/comp(L_x,x,yz,comp(R_y,y,z,L_z))
    by A5,Th60;
    A88:comp(R_x,x,yz,L_yz) =
    comp(R_x,x,yz,comp(L_y,y,z,L_z)) \/comp(R_x,x,yz,comp(R_y,y,z,R_z))
    by A5,Th60;
    A89: comp(L_x,x,yz,comp(L_y,y,z,R_z)) <==>
    comp(comp(L_x,x,y,L_y),xy,z,R_z) by A8;
    A90: comp(L_x,x,yz,comp(R_y,y,z,L_z)) <==>
    comp(comp(L_x,x,y,R_y),xy,z,L_z) by A8;
    A91:comp(R_x,x,yz,comp(L_y,y,z,L_z)) <==>
    comp(comp(R_x,x,y,L_y),xy,z,L_z) by A8;
    A92:comp(R_x,x,yz,comp(R_y,y,z,R_z)) <==>
    comp(comp(R_x,x,y,R_y),xy,z,R_z) by A8;
    A93: comp(L_x,x,yz,R_yz) <==>
    comp(comp(L_x,x,y,L_y),xy,z,R_z)\/comp(comp(L_x,x,y,R_y),xy,z,L_z)
    by A87,A89,A90,SURREALO:31;
    comp(R_x,x,yz,L_yz) <==>
    comp(comp(R_x,x,y,L_y),xy,z,L_z)\/ comp(comp(R_x,x,y,R_y),xy,z,R_z)
    by A88,A91,A92,SURREALO:31;
    then
    A94: R_(x*yz) <==>
    (comp(comp(L_x,x,y,L_y),xy,z,R_z)\/comp(comp(L_x,x,y,R_y),xy,z,L_z))\/
    (comp(comp(R_x,x,y,L_y),xy,z,L_z)\/ comp(comp(R_x,x,y,R_y),xy,z,R_z))
    by A6,A93,SURREALO:31;
    A95: (comp(comp(L_x,x,y,L_y),xy,z,R_z)\/comp(comp(L_x,x,y,R_y),xy,z,L_z))\/
    (comp(comp(R_x,x,y,L_y),xy,z,L_z)\/ comp(comp(R_x,x,y,R_y),xy,z,R_z))
    =
    ((comp(comp(L_x,x,y,L_y),xy,z,R_z)\/comp(comp(L_x,x,y,R_y),xy,z,L_z))\/
    comp(comp(R_x,x,y,L_y),xy,z,L_z))\/ comp(comp(R_x,x,y,R_y),xy,z,R_z)
    by XBOOLE_1:4
    .=( comp(comp(L_x,x,y,L_y),xy,z,R_z)\/
    (comp(comp(L_x,x,y,R_y),xy,z,L_z)\/
    comp(comp(R_x,x,y,L_y),xy,z,L_z)))\/ comp(comp(R_x,x,y,R_y),xy,z,R_z)
    by XBOOLE_1:4
    .= (comp(comp(L_x,x,y,L_y),xy,z,R_z)\/comp(comp(R_x,x,y,R_y),xy,z,R_z))\/
    (comp(comp(L_x,x,y,R_y),xy,z,L_z)\/comp(comp(R_x,x,y,L_y),xy,z,L_z))
    by XBOOLE_1:4;
    A96: comp(L_xy,xy,z,R_z) =
    comp(comp(L_x,x,y,L_y),xy,z,R_z)\/comp(comp(R_x,x,y,R_y),xy,z,R_z)
    by A4,Th68;
    comp(R_xy,xy,z,L_z) =
    comp(comp(L_x,x,y,R_y),xy,z,L_z)\/comp(comp(R_x,x,y,L_y),xy,z,L_z)
    by A4,Th68;
    hence thesis by A6,A7,A86,SURREALO:29,A94,A95,A96;
  end;
  for D be Ordinal holds P[D] from ORDINAL1:sch 2(A1);
  then P[born x (+) born y (+) born z];
  hence thesis;
end;
