reserve X for non empty BCIStr_1;
reserve d for Element of X;
reserve n,m,k for Nat;
reserve f for sequence of  the carrier of X;

theorem
  for X being BCI-Algebra_with_Condition(S) st X is p-Semisimple holds
  for x,y being Element of X holds x*y = x\(0.X\y)
proof
  let X be BCI-Algebra_with_Condition(S);
  assume
A1: X is p-Semisimple;
  for x,y being Element of X holds x*y = x\(0.X\y)
  proof
    let x,y be Element of X;
    set z1 = x\(0.X\y);
    set z2 = x * y;
    ((x\(0.X\y))\x)\y = ((x\x)\(0.X\y))\y by BCIALG_1:7
      .= (0.X\(0.X\y))\y by BCIALG_1:def 5
      .= (0.X\y)\(0.X\y) by BCIALG_1:7
      .= 0.X by BCIALG_1:def 5;
    then (x\(0.X\y))\x <= y;
    then z1 <= z2 by Lm2;
    then
A2: z1\z2 = 0.X;
A3: for t being Element of X st t\x <= y holds t <= (x\(0.X\y))
    proof
      let t be Element of X;
      assume t\x <= y;
      then (t\x)\y = 0.X;
      then t\(x\(0.X\y)) = t\(x\(0.X\(t\x))) by A1,Th4
        .= t\(x\(x\(t\0.X))) by A1,BCIALG_1:57
        .= t\(t\0.X) by A1
        .= t\t by BCIALG_1:2
        .= 0.X by BCIALG_1:def 5;
      hence thesis;
    end;
    (x*y)\x <= y by Lm2;
    then z2 <= z1 by A3;
    then z2\z1 = 0.X;
    hence thesis by A2,BCIALG_1:def 7;
  end;
  hence thesis;
end;
