reserve X for RealUnitarySpace;
reserve x for Point of X;
reserve i, n for Nat;

theorem Th6:
  for X st the addF of X is commutative associative & the addF of X
  is having_a_unity for Y be Subset of X holds Y is weakly_summable_set implies
ex x st for L be linear-Functional of X st L is Lipschitzian
for e be Real st
e > 0
  ex Y0 be finite Subset of X st Y0 is non empty & Y0 c= Y & for Y1 be finite
Subset of X st Y0 c= Y1 & Y1 c= Y holds |.(L.x)-(setopfunc(Y1,the carrier of
  X,REAL, L, addreal)).| < e
proof
  let X such that
A1: the addF of X is commutative associative & the addF of X is having_a_unity;
  let Y be Subset of X;
  assume Y is weakly_summable_set;
  then consider x such that
A2: for L be linear-Functional of X st L is Lipschitzian
   for e be Real st e >
  0 ex Y0 be finite Subset of X st Y0 is non empty & Y0 c= Y & for Y1 be finite
  Subset of X st Y0 c= Y1 & Y1 c= Y holds |.L.(x-setsum(Y1)).| < e;
  take x;
  now
    let L be linear-Functional of X such that
A3: L is Lipschitzian;
    now
      let e be Real;
      assume e > 0;
      then consider Y0 be finite Subset of X such that
A4:   Y0 is non empty and
A5:   Y0 c= Y and
A6:   for Y1 be finite Subset of X st Y0 c= Y1 & Y1 c= Y holds |.L.
      (x- setsum(Y1)).| < e by A2,A3;
      take Y0;
      now
        set x1 = x;
        let Y1 be finite Subset of X such that
A7:     Y0 c= Y1 and
A8:     Y1 c= Y;
        set y1 = setsum(Y1);
        set r = L.(x-setsum(Y1));
        Y1 <> {} by A4,A7;
        then r = L.x1 - L.y1 & L.y1=setopfunc(Y1,the carrier of X,REAL, L,
        addreal) by A1,Th5,HAHNBAN:19;
        hence |.(L.x)-(setopfunc(Y1,the carrier of X,REAL, L, addreal)).| < e
        by A6,A7,A8;
      end;
      hence Y0 is non empty & Y0 c= Y & for Y1 be finite Subset of X st Y0 c=
Y1 & Y1 c= Y holds |.(L.x)-(setopfunc(Y1,the carrier of X,REAL, L, addreal)).|
      < e by A4,A5;
    end;
    hence
    for e be Real st e > 0
   ex Y0 be finite Subset of X st Y0 is non empty
& Y0 c= Y & for Y1 be finite Subset of X st Y0 c= Y1 & Y1 c= Y holds |.(L.x)-
    (setopfunc(Y1,the carrier of X,REAL, L, addreal)).| < e;
  end;
  hence thesis;
end;
