reserve Al for QC-alphabet;
reserve p,q,p1,p2,q1 for Element of CQC-WFF(Al),
  k for Element of NAT,
  f,f1,f2,g for FinSequence of CQC-WFF(Al),
  a,b,b1,b2,c,i,n for Nat;

theorem Th6:
  seq(a,b),b are_equipotent
proof
  defpred P[Nat] means seq(a,$1),$1 are_equipotent;
A1: for n being Nat st P[n] holds P[n+1]
  proof
    let n be Nat such that
A2: seq(a,n),n are_equipotent;
    reconsider i = a+n as Nat;
A3: Segm(n+1) = Segm n \/ { n } by AFINSQ_1:2;
A4: now
      assume seq(a,n) meets { i+1 };
      then consider x being object such that
A5:   x in seq(a,n) and
A6:   x in { i+1 } by XBOOLE_0:3;
A7:   not i+1 <= i by NAT_1:13;
      x = i+1 by A6,TARSKI:def 1;
      hence contradiction by A5,A7,Th1;
    end;
A8: now
      assume n meets { n };
      then consider x being object such that
A9:   x in n and
A10:  x in { n } by XBOOLE_0:3;
A:    x = n by A10,TARSKI:def 1;
      reconsider x as set by TARSKI:1;
      not x in x; 
      hence contradiction by A,A9;
    end;
    seq(a,n+1) = seq(a,n) \/ { i+1 } & { i+1 },{ n } are_equipotent
    by Th5,CARD_1:28;
    hence thesis by A2,A3,A8,A4,CARD_1:31;
  end;
A11: P[0] by Th2;
  for n being Nat holds P[n] from NAT_1:sch 2(A11,A1);
  hence thesis;
end;
