
theorem Th6:
  for C being FormalContext for A being Subset of the carrier' of C
  holds A c= (ObjectDerivation(C)).((AttributeDerivation(C)).A)
proof
  let C be FormalContext;
  let A be Subset of the carrier' of C;
  set O = {o where o is Object of C : for a being Attribute of C st a in A
  holds o is-connected-with a};
  for x being object holds x in O implies x in the carrier of C
  proof
    let x be object;
    assume x in O;
    then
    ex x9 being Object of C st x9 = x & for a being Attribute of C st a in
    A holds x9 is-connected-with a;
    hence thesis;
  end;
  then reconsider O as Subset of the carrier of C by TARSKI:def 3;
  let x be object;
  assume
A1: x in A;
  then reconsider x as Attribute of C;
A2: for o being Object of C st o in O holds o is-connected-with x
  proof
    let o be Object of C;
    assume o in O;
    then
    ex o9 being Object of C st o9 = o & for a being Attribute of C st a in
    A holds o9 is-connected-with a;
    hence thesis by A1;
  end;
  (ObjectDerivation(C)).O = {a where a is Attribute of C : for o being
  Object of C st o in O holds o is-connected-with a} by Def2;
  then x in (ObjectDerivation(C)).O by A2;
  hence thesis by Def3;
end;
