 reserve n,k for Nat;
 reserve L for comRing;
 reserve R for domRing;
 reserve x0 for positive Real;

theorem Lm1:
  for n be Nat,
      f be Element of the carrier of Polynom-Ring F_Rat holds
    n*f = In(n,F_Rat)*f
   proof
     set R = F_Rat,
     PR = Polynom-Ring F_Rat;
     let n be Nat,
     f be Element of the carrier of Polynom-Ring F_Rat;
     defpred P[Nat] means $1*f = In($1,F_Rat)*f;
A1:  P[0]
     proof
       In(0,F_Rat)*f = 0_.R by POLYNOM5:26,GAUSSINT:def 14
       .= 0.PR by POLYNOM3:def 10;
       hence thesis by BINOM:12;
     end;
A2:  for k be Nat holds P[k] implies P[k+1]
     proof
       let k be Nat;
       assume
A3:    P[k];
       reconsider r = In(k,F_Rat) as Element of R;
A4:    In(k+1,F_Rat) = r+1.R by GAUSSINT:def 14;
A5:    In(k,F_Rat)*f + f = r*f + 1.R*f
       .= In(k+1,F_Rat) *f by A4,POLYALG1:7;
       In(k,F_Rat)*f + f
        = k*f + f by A3,POLYNOM3:def 10
       .= k*f + 1*f by BINOM:13 .= (k+1)*f by BINOM:15;
       hence thesis by A5;
     end;
     for k be Nat holds P[k] from NAT_1:sch 2(A1,A2);
     hence thesis;
   end;
