
theorem lemNor1a:
for F being Field,
    E being FieldExtension of F
for G being non empty FinSequence of the carrier of Polynom-Ring F
for q being non constant Polynomial of F st q = Product G
holds q splits_in E iff
      for i being Element of dom G, p being Polynomial of F
      st p = G.i holds p is constant or p splits_in E
proof
let F be Field, E be FieldExtension of F;
let G be non empty FinSequence of the carrier of Polynom-Ring F;
let q be non constant Polynomial of F;
assume AS: q = Product G;
J: the carrier of Polynom-Ring F c= the carrier of Polynom-Ring E &
q in the carrier of Polynom-Ring F by FIELD_4:10,POLYNOM3:def 10; then
reconsider q1 = q as Polynomial of E by POLYNOM3:def 10;
H: q is Element of the carrier of Polynom-Ring F &
   q1 is Element of the carrier of Polynom-Ring E by POLYNOM3:def 10;
deg q > 0 by RATFUNC1:def 2; then
deg q1 > 0 by H,FIELD_4:20; then
reconsider q1 as non constant Polynomial of E by RATFUNC1:def 2;
rng G c= the carrier of Polynom-Ring F by FINSEQ_1:def 4; then
rng G c= the carrier of Polynom-Ring E by J; then
reconsider G1 = G as non empty
        FinSequence of the carrier of Polynom-Ring E by FINSEQ_1:def 4;
Polynom-Ring F is Subring of Polynom-Ring E by FIELD_4:def 1; then
B: Product G1 = Product G by Eprod;
A: now assume q splits_in E; then
   consider a being non zero Element of E, q2 being Ppoly of E such that
   A3: q = a * q2 by FIELD_4:def 5;
   A1: q1 splits_in E by A3,FIELD_4:def 5;
   now let i be Element of dom G, p be Polynomial of F;
     assume A2: p = G.i;
     reconsider p1 = p as Polynomial of E by FIELD_4:8;
     H: p is Element of the carrier of Polynom-Ring F &
        p1 is Element of the carrier of Polynom-Ring E by POLYNOM3:def 10;
     per cases by B,A1,A2,AS,lemNor1ah;
     suppose p1 is constant; then
       deg p1 <= 0 by RATFUNC1:def 2; then
       deg p <= 0 by H,FIELD_4:20;
       hence p is constant or p splits_in E by RATFUNC1:def 2;
       end;
     suppose p1 splits_in E; then
       consider b being non zero Element of E, p2 being Ppoly of E such that
       A4: p1 = b * p2 by FIELD_4:def 5;
       thus p is constant or p splits_in E by A4,FIELD_4:def 5;
       end;
     end;
   hence for i being Element of dom G, p being Polynomial of F
         st p = G.i holds p is constant or p splits_in E;
   end;
now assume A1: for i being Element of dom G, p being Polynomial of F
      st p = G.i holds p is constant or p splits_in E;
  now let i be Element of dom G1, p be Polynomial of E;
     assume A2: p = G1.i; then
     p = G/.i by PARTFUN1:def 6; then
     p is Element of the carrier of Polynom-Ring F; then
     reconsider p1 = p as Polynomial of F;
     H: p1 is Element of the carrier of Polynom-Ring F &
        p is Element of the carrier of Polynom-Ring E by POLYNOM3:def 10;
     per cases by A1,A2;
     suppose p1 is constant; then
       deg p1 <= 0 by RATFUNC1:def 2; then
       deg p <= 0 by H,FIELD_4:20;
       hence p is constant or p splits_in E by RATFUNC1:def 2;
       end;
     suppose p1 splits_in E; then
       consider b being non zero Element of E, p2 being Ppoly of E such that
       A4: p1 = b * p2 by FIELD_4:def 5;
       thus p is constant or p splits_in E by A4,FIELD_4:def 5;
       end;
    end;
  then q1 splits_in E by B,AS,lemNor1ah; then
  consider a being non zero Element of E, q2 being Ppoly of E such that
  A3: q1 = a * q2 by FIELD_4:def 5;
  thus q splits_in E by A3,FIELD_4:def 5;
  end;
hence thesis by A;
end;
