
theorem Th6:
  for T being TopSpace, S being non empty TopStruct, f being
Function of T,S st for A being Subset of S holds A is closed iff f"A is closed
  holds S is TopSpace
proof
  let T be TopSpace, S be non empty TopStruct, f be Function of T,S;
  assume
A1: for A being Subset of S holds A is closed iff f"A is closed;
A2: for A,B being Subset of S st A is closed & B is closed holds A \/ B is
  closed
  proof
    let A,B be Subset of S;
    assume A is closed & B is closed;
    then f"A is closed & f"B is closed by A1;
    then f"A \/ f"B is closed by TOPS_1:9;
    then f"(A \/ B) is closed by RELAT_1:140;
    hence thesis by A1;
  end;
  {}T is closed & f"{}={};
  then
A3: {}S is closed by A1;
A4: for F being Subset-Family of S st F is closed holds meet F is closed
  proof
    let F be Subset-Family of S;
    assume
A5: F is closed;
    per cases;
    suppose
      F = {}S;
      hence thesis by A3,SETFAM_1:def 1;
    end;
    suppose
A6:   F <> {};
      set F1 = {f"A where A is Subset of S : A in F};
      ex A being set st A in F
      proof
        set A = the Element of F;
        take A;
        thus thesis by A6;
      end;
      then consider A being Subset of S such that
A7:   A in F;
      reconsider A as Subset of S;
A8:   f"A in F1 by A7;
      F1 c= bool the carrier of T
      proof
        let B be object;
        assume B in F1;
        then ex A being Subset of S st B=f"A & A in F;
        hence thesis;
      end;
      then reconsider F1 as Subset-Family of T;
A9:   meet(F1) c= f"(meet F)
      proof
        let x be object;
        assume
A10:    x in meet(F1);
        for A be set st A in F holds f.x in A
        proof
          let A be set;
          assume
A11:      A in F;
          then reconsider A as Subset of S;
          f"A in F1 by A11;
          then x in f"A by A10,SETFAM_1:def 1;
          hence thesis by FUNCT_1:def 7;
        end;
        then
A12:    f.x in meet F by A6,SETFAM_1:def 1;
        x in the carrier of T by A10;
        then x in dom f by FUNCT_2:def 1;
        hence thesis by A12,FUNCT_1:def 7;
      end;
      F1 is closed
      proof
        let B be Subset of T;
        assume B in F1;
        then consider A being Subset of S such that
A13:    f"A = B and
A14:    A in F;
        A is closed by A5,A14;
        hence thesis by A1,A13;
      end;
      then
A15:  meet F1 is closed by TOPS_2:22;
      f"(meet F) c= meet(F1)
      proof
        let x be object;
        assume
A16:    x in f"(meet F);
        then
A17:    f.x in meet F by FUNCT_1:def 7;
A18:    x in dom f by A16,FUNCT_1:def 7;
        for B be set st B in F1 holds x in B
        proof
          let B be set;
          assume B in F1;
          then consider A being Subset of S such that
A19:      B = f"A and
A20:      A in F;
          f.x in A by A17,A20,SETFAM_1:def 1;
          hence thesis by A18,A19,FUNCT_1:def 7;
        end;
        hence thesis by A8,SETFAM_1:def 1;
      end;
      then meet(F1) = f"(meet F) by A9;
      hence thesis by A1,A15;
    end;
  end;
  f"([#]S) = [#]T by TOPS_2:41;
  then [#]S is closed by A1;
  hence thesis by A3,A2,A4,Th5;
end;
