reserve p,p1,p2,q1,q2 for Point of TOP-REAL 2,
  P1,P2 for Subset of TOP-REAL 2,
  f,f1,f2,g1,g2 for FinSequence of TOP-REAL 2,
  n,m,i,j,k for Nat,
  G,G1 for Go-board,
  x,y for set;

theorem
  for P1,P2,p1,p2,q1,q2 st P1 is_S-P_arc_joining p1,q1 & P2
is_S-P_arc_joining p2,q2 & (for p st p in P1 \/ P2 holds p1`1<=p`1 & p`1<=q1`1)
  & (for p st p in P1 \/ P2 holds p2`2<=p`2 & p`2<=q2`2) holds P1 meets P2
proof
  let P1,P2,p1,p2,q1,q2;
  assume that
A1: P1 is_S-P_arc_joining p1,q1 and
A2: P2 is_S-P_arc_joining p2,q2 and
A3: for p st p in P1 \/ P2 holds p1`1<=p`1 & p`1<=q1`1 and
A4: for p st p in P1 \/ P2 holds p2`2<=p`2 & p`2<=q2`2;
  consider f1 such that
A5: f1 is being_S-Seq and
A6: P1=L~f1 and
A7: p1=f1/.1 and
A8: q1=f1/.len f1 by A1,TOPREAL4:def 1;
  len f1 <> 0 by A5,TOPREAL1:def 8;
  then reconsider f1 as non empty FinSequence of TOP-REAL 2;
A9: Seg len f1=dom f1 by FINSEQ_1:def 3;
  consider f2 such that
A10: f2 is being_S-Seq and
A11: P2=L~f2 and
A12: p2=f2/.1 and
A13: q2=f2/.len f2 by A2,TOPREAL4:def 1;
  len f2 <> 0 by A10,TOPREAL1:def 8;
  then reconsider f2 as non empty FinSequence of TOP-REAL 2;
A14: Seg len f2=dom f2 by FINSEQ_1:def 3;
  set x1 = X_axis(f1), y1 = Y_axis(f1), x2 = X_axis(f2), y2 = Y_axis(f2);
A15: Seg len x1=dom x1 & len x1= len f1 by FINSEQ_1:def 3,GOBOARD1:def 1;
A16: dom y2=Seg len y2 & len y2=len f2 by FINSEQ_1:def 3,GOBOARD1:def 2;
A17: 2<=len f2 by A10,TOPREAL1:def 8;
  then
A18: 1<=len f2 by XXREAL_0:2;
  then 1 in dom f2 by FINSEQ_3:25;
  then
A19: y2.1=p2`2 by A12,A14,A16,GOBOARD1:def 2;
  len f2 in dom f2 by A18,FINSEQ_3:25;
  then
A20: y2.(len f2)=q2`2 by A13,A14,A16,GOBOARD1:def 2;
A21: y2 lies_between y2.1, y2.len f2
  proof
    let n;
    set q = f2/.n;
    assume
A22: n in dom y2;
    then q in L~f2 by A17,A14,A16,GOBOARD1:1;
    then
A23: q in P1 \/ P2 by A11,XBOOLE_0:def 3;
    y2.n=q`2 by A22,GOBOARD1:def 2;
    hence thesis by A4,A19,A20,A23;
  end;
A24: 2<=len f1 by A5,TOPREAL1:def 8;
  then
A25: 1<=len f1 by XXREAL_0:2;
  then 1 in dom f1 by FINSEQ_3:25;
  then
A26: x1.1=p1`1 by A7,A9,A15,GOBOARD1:def 1;
  len f1 in dom f1 by A25,FINSEQ_3:25;
  then
A27: x1.(len f1)=q1`1 by A8,A9,A15,GOBOARD1:def 1;
A28: x1 lies_between x1.1, x1.len f1
  proof
    let n;
    set q=f1/.n;
    assume
A29: n in dom x1;
    then q in L~f1 by A24,A9,A15,GOBOARD1:1;
    then
A30: q in P1 \/ P2 by A6,XBOOLE_0:def 3;
    x1.n=q`1 by A29,GOBOARD1:def 1;
    hence thesis by A3,A26,A27,A30;
  end;
A31: dom x2=Seg len x2 & len x2=len f2 by FINSEQ_1:def 3,GOBOARD1:def 1;
A32: x2 lies_between x1.1, x1.len f1
  proof
    let n;
    set q=f2/.n;
    assume
A33: n in dom x2;
    then q in L~f2 by A17,A14,A31,GOBOARD1:1;
    then
A34: q in P1 \/ P2 by A11,XBOOLE_0:def 3;
    x2.n=q`1 by A33,GOBOARD1:def 1;
    hence thesis by A3,A26,A27,A34;
  end;
A35: dom y1=Seg len y1 & len y1=len f1 by FINSEQ_1:def 3,GOBOARD1:def 2;
A36: y1 lies_between y2.1, y2.len f2
  proof
    let n;
    set q=f1/.n;
    assume
A37: n in dom y1;
    then q in L~f1 by A24,A9,A35,GOBOARD1:1;
    then
A38: q in P1 \/ P2 by A6,XBOOLE_0:def 3;
    y1.n=q`2 by A37,GOBOARD1:def 2;
    hence thesis by A4,A19,A20,A38;
  end;
A39: f2 is one-to-one special by A10,TOPREAL1:def 8;
  f1 is one-to-one special by A5,TOPREAL1:def 8;
  hence thesis by A6,A11,A39,A24,A17,A28,A32,A36,A21,Th5;
end;
