reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;

theorem
  [i,j] in Indices G & [i,j+n] in Indices G implies dist(G*(i,j),G*(i,j+
  n)) = G*(i,j+n)`2 - G*(i,j)`2
proof
  assume that
A1: [i,j] in Indices G and
A2: [i,j+n] in Indices G;
  set x = G*(i,j), y = G*(i,j+n);
  per cases;
  suppose
    n = 0;
    hence thesis by TOPREAL6:93;
  end;
  suppose
A3: n <> 0;
A4: j+n <= width G by A2,MATRIX_0:32;
A5: 1 <= i & i <= len G by A1,MATRIX_0:32;
A6: 1 <= j+n by A2,MATRIX_0:32;
A7: 1 <= j by A1,MATRIX_0:32;
    1 <= n by A3,NAT_1:14;
    then j < j+n by NAT_1:19;
    then x`2 < y`2 by A4,A7,A5,GOBOARD5:4;
    then
A8: x`2 - x`2 < y`2 - x`2 by XREAL_1:14;
    j <= width G by A1,MATRIX_0:32;
    then
A9: x`1 = G*(i,1)`1 by A7,A5,GOBOARD5:2
      .= y`1 by A6,A4,A5,GOBOARD5:2;
    thus dist(G*(i,j),G*(i,j+n)) = sqrt ((x`1-y`1)^2 + (x`2-y`2)^2) by
TOPREAL6:92
      .= |.x`2-y`2.| by A9,COMPLEX1:72
      .= |.-(x`2-y`2).| by COMPLEX1:52
      .= G*(i,j+n)`2 - G*(i,j)`2 by A8,ABSVALUE:def 1;
  end;
end;
