reserve AFP for AffinPlane;
reserve a,a9,b,b9,c,c9,d,d9,o,p,p9,q,q9,r,s,t,x,y,z for Element of AFP;
reserve A,A9,C,D,P,B9,M,N,K for Subset of AFP;
reserve f for Permutation of the carrier of AFP;

theorem Th6:
  (for a,b,K st a,b // K & not a in K ex f st f is_Sc K & f.a=b)
  implies AFP is Moufangian
proof
  assume
A1: for a,b,K st a,b // K & not a in K ex f st f is_Sc K & f.a=b;
  now
    let o,K,c,c9,a,b,a9,b9;
    assume that
A2: o in K and
A3: c in K and
A4: c9 in K and
A5: K is being_line and
A6: LIN o,a,a9 and
A7: LIN o,b,b9 and
A8: not a in K and
A9: a,b // K and
A10: a9,b9 // K and
A11: a,c // a9,c9;
    consider f such that
A12: f is_Sc K and
A13: f.a=b by A1,A8,A9;
A14: f is collineation by A12;
A15: a,b // a9,b9 by A5,A9,A10,AFF_1:31;
A16: f.a9=b9
    proof
      set x=f.a9;
A17:  now
        f.o=o by A2,A12;
        then
A18:    LIN o,b,x by A6,A13,A14,TRANSGEO:88;
        a9,x // K by A12;
        then
A19:    a,b // a9,x by A5,A9,AFF_1:31;
        assume a<>b;
        hence thesis by A2,A6,A7,A8,A9,A15,A19,A18,AFF_1:46,56;
      end;
      now
        assume
A20:    a=b;
        then f=id the carrier of AFP by A8,A12,A13,Th5;
        then x=a9 by FUNCT_1:18;
        hence thesis by A2,A6,A7,A8,A10,A20,AFF_1:47;
      end;
      hence thesis by A17;
    end;
A21: f.c9=c9 by A4,A12;
    f.c = c by A3,A12;
    hence b,c // b9,c9 by A11,A13,A14,A21,A16,TRANSGEO:87;
  end;
  hence thesis by Lm2;
end;
