reserve n for Nat;

theorem Th6:
  for C be compact connected non vertical non horizontal Subset of TOP-REAL 2
  for f be FinSequence of TOP-REAL 2
  for k be Nat st 1 <= k & k+1 <= len f &
  f is_sequence_on Gauge(C,n) holds
  dist(f/.k,f/.(k+1)) = (N-bound C - S-bound C)/2|^n or
  dist(f/.k,f/.(k+1)) = (E-bound C - W-bound C)/2|^n
proof
  let C be compact connected non vertical non horizontal Subset of TOP-REAL 2;
  let f be FinSequence of TOP-REAL 2;
  let k be Nat;
  assume that
A1: 1 <= k and
A2: k+1 <= len f;
  assume f is_sequence_on Gauge(C,n);
  then consider i1,j1,i2,j2 be Nat such that
A3: [i1,j1] in Indices Gauge(C,n) and
A4: f/.k = Gauge(C,n)*(i1,j1) and
A5: [i2,j2] in Indices Gauge(C,n) and
A6: f/.(k+1) = Gauge(C,n)*(i2,j2) and
A7: i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or
  i1 = i2+1 & j1 = j2 or i1 = i2 & j1 = j2+1 by A1,A2,JORDAN8:3;
  per cases by A7;
  suppose i1 = i2 & j1+1 = j2;
    hence thesis by A3,A4,A5,A6,GOBRD14:9;
  end;
  suppose i1+1 = i2 & j1 = j2;
    hence thesis by A3,A4,A5,A6,GOBRD14:10;
  end;
  suppose i1 = i2+1 & j1 = j2;
    hence thesis by A3,A4,A5,A6,GOBRD14:10;
  end;
  suppose i1 = i2 & j1 = j2+1;
    hence thesis by A3,A4,A5,A6,GOBRD14:9;
  end;
end;
