reserve C for Simple_closed_curve,
  i, j, n for Nat,
  p for Point of TOP-REAL 2;

theorem Th6:
  for C being compact Subset of TOP-REAL 2 holds BDD C <> {}
  implies W-bound C <= W-bound BDD C
proof
  let C be compact Subset of TOP-REAL 2;
  set WC = W-bound C, WB = W-bound BDD C;
  set hal = (WB + WC)/2;
  assume that
A1: BDD C <> {} and
A2: WC > WB;
A3: hal < WC by A2,XREAL_1:226;
  now
    per cases;
    suppose
      for q1 being Point of TOP-REAL 2 st q1 in BDD C holds q1`1 >= hal;
      hence contradiction by A1,A2,Lm9,XREAL_1:226;
    end;
    suppose
      ex q1 being Point of TOP-REAL 2 st q1 in BDD C & q1`1 < hal;
      then consider q1 being Point of TOP-REAL 2 such that
A4:   q1 in BDD C and
A5:   q1`1 < hal;
      set Q = |[(WC + q1`1)/2,q1`2]|;
      set WH = west_halfline Q;
A6:   Q`1 = (WC + q1`1)/2 by EUCLID:52;
A7:   q1`1 < WC by A3,A5,XXREAL_0:2;
      WH misses C
      proof
A8:     Q`1 < WC by A7,A6,XREAL_1:226;
        assume WH meets C;
        then consider y being object such that
A9:     y in WH /\ C by XBOOLE_0:4;
A10:    y in C by A9,XBOOLE_0:def 4;
A11:    y in WH by A9,XBOOLE_0:def 4;
        reconsider y as Point of TOP-REAL 2 by A9;
        y`1 <= Q`1 by A11,TOPREAL1:def 13;
        then y`1 < WC by A8,XXREAL_0:2;
        hence thesis by A10,PSCOMP_1:24;
      end;
      then
A12:  WH c= UBD C by JORDAN2C:126;
A13:  q1`2 = Q`2 by EUCLID:52;
      q1`1 < Q`1 by A7,A6,XREAL_1:226;
      then q1 in WH by A13,TOPREAL1:def 13;
      then q1 in BDD C /\ UBD C by A4,A12,XBOOLE_0:def 4;
      then BDD C meets UBD C;
      hence contradiction by JORDAN2C:24;
    end;
  end;
  hence thesis;
end;
