reserve i,j,k,n for Nat;

theorem
  for C being compact connected non vertical non horizontal non empty
Subset of TOP-REAL 2 holds W-min C in right_cell(Rotate(Cage(C,n),W-min L~Cage(
  C,n)),1)
proof
  let C be compact connected non vertical non horizontal non empty Subset of
  TOP-REAL 2;
  set f = Cage(C,n);
  set G = Gauge(C,n);
  consider j being Nat such that
A1: 1 <= j and
A2: j <= width G and
A3: W-min L~f = G*(1,j) by JORDAN1D:30;
A4: len G >= 4 by JORDAN8:10;
  then
A5: 1 <= len G by XXREAL_0:2;
  set k = (W-min L~f)..f;
A6: W-min L~f in rng f by SPRECT_2:43;
  then
A7: k in dom f & f.k = W-min L~f by FINSEQ_4:19,20;
  then
A8: f/.k = W-min L~f by PARTFUN1:def 6;
A9: now
A10: 1 < (W-min L~f)..f by Th1;
A11: 1 in dom f by A6,FINSEQ_3:31;
    assume k = len f;
    then f/.1 = W-min L~f by A8,FINSEQ_6:def 1;
    then f.1 = W-min L~f by A11,PARTFUN1:def 6;
    hence contradiction by A11,A10,FINSEQ_4:24;
  end;
  1 <= len G by A4,XXREAL_0:2;
  then
A12: [1,j] in Indices G by A1,A2,MATRIX_0:30;
  then
A13: [1,j] in Indices GoB f by JORDAN1H:44;
  k <= len f by A6,FINSEQ_4:21;
  then k < len f by A9,XXREAL_0:1;
  then
A14: k+1 <= len f by NAT_1:13;
  f/.k = G*(1,j) by A3,A7,PARTFUN1:def 6;
  then
A15: f/.k = (GoB f)*(1,j) by JORDAN1H:44;
  set p = W-min C;
A16: f is_sequence_on G by JORDAN9:def 1;
A17: 1 <= k+1 by NAT_1:11;
  then
A18: k+1 in dom f by A14,FINSEQ_3:25;
A19: k+1 in dom f by A14,A17,FINSEQ_3:25;
  then consider ki,kj being Nat such that
A20: [ki,kj] in Indices G and
A21: f/.(k+1) = G*(ki,kj) by A16,GOBOARD1:def 9;
A22: 1 <= kj & ki <= len G by A20,MATRIX_0:32;
A23: 1 <= k by Th1;
  then
A24: (f/.(k+1))`1 = W-bound L~Cage(C,n) by A8,A14,JORDAN1E:22;
  then G*(1,j)`1 = G*(ki,kj)`1 by A3,A21,EUCLID:52;
  then
A25: ki = 1 by A20,A12,JORDAN1G:7;
  2 <= len f by GOBOARD7:34,XXREAL_0:2;
  then f/.(k+1) in W-most L~f by A24,A19,GOBOARD1:1,SPRECT_2:12;
  then G*(1,j)`2 <= G*(ki,kj)`2 by A3,A21,PSCOMP_1:31;
  then
A26: j <= kj by A2,A25,A22,GOBOARD5:4;
  [ki,kj] in Indices GoB f & f/.(k+1) = (GoB f)*(ki,kj) by A20,A21,JORDAN1H:44;
  then |.1-ki.|+|.j-kj.| = 1 by A6,A18,A13,A15,FINSEQ_4:20,GOBOARD5:12;
  then
A27: 0+|.j-kj.| = 1 by A25,ABSVALUE:2;
  then
A28: f/.(k+1) = G*(1,j+1) by A21,A25,A26,SEQM_3:41;
A29: kj = j+1 by A26,A27,SEQM_3:41;
  then 1 <= j+1 & j+1 <= width G by A20,MATRIX_0:32;
  then [1,j+1] in Indices G by A5,MATRIX_0:30;
  then
A30: right_cell(f,k,G) = cell(G,1,j) by A3,A16,A23,A8,A14,A12,A28,GOBRD13:22;
A31: now
    len G = width G by JORDAN8:def 1;
    then
A32: j+1 <= len G by A20,A29,MATRIX_0:32;
    1 <= j+1 by A20,A29,MATRIX_0:32;
    then
A33: G*(2,j+1)`1 = W-bound C by A32,JORDAN8:11;
    assume
A34: not p in right_cell(f,k,G);
    j+1 <= width G by A20,A29,MATRIX_0:32;
    then
A35: j < width G by NAT_1:13;
A36: 2 <= len G by A4,XXREAL_0:2;
    1 < len G by A4,XXREAL_0:2;
    then LSeg(G*(1+1,j),G*(1+1,j+1)) c= cell(G,1,j) by A1,A35,GOBOARD5:18;
    then
A37: not p in LSeg(G*(2,j),G*(2,j+1)) by A30,A34;
A38: 1 <= j+1 & j+1 <= width G by A20,A29,MATRIX_0:32;
    j <= len G by A2,JORDAN8:def 1;
    then
A39: G*(2,j)`1 = W-bound C by A1,JORDAN8:11;
    p`1 = W-bound C by EUCLID:52;
    then
A40: p`2 > G*(2,j+1)`2 or p`2 < G*(2,j)`2 by A37,A39,A33,GOBOARD7:7;
    per cases by A1,A2,A40,A38,A36,GOBOARD5:1;
    suppose
A41:  p`2 > G*(1,j+1)`2;
      cell(G,1,j) meets C by A23,A14,A30,JORDAN9:31;
      then cell(G,1,j) /\ C <> {} by XBOOLE_0:def 7;
      then consider c being object such that
A42:  c in cell(G,1,j) /\ C by XBOOLE_0:def 1;
      reconsider c as Element of TOP-REAL 2 by A42;
A43:  c in cell(G,1,j) by A42,XBOOLE_0:def 4;
A44:  c in C by A42,XBOOLE_0:def 4;
      then
A45:  c`1 >= W-bound C by PSCOMP_1:24;
A46:  1+1 <= len G & j+1 <= width G by A4,A20,A29,MATRIX_0:32,XXREAL_0:2;
      then c`1 <= G*(1+1,j)`1 by A1,A43,JORDAN9:17;
      then c in W-most C by A39,A44,A45,SPRECT_2:12,XXREAL_0:1;
      then
A47:  c`2 >= p`2 by PSCOMP_1:31;
      c`2 <= G*(1,j+1)`2 by A1,A43,A46,JORDAN9:17;
      hence contradiction by A41,A47,XXREAL_0:2;
    end;
    suppose
A48:  p`2 < G*(1,j)`2;
      west_halfline p meets L~f by JORDAN1A:54,SPRECT_1:13;
      then consider r being object such that
A49:  r in west_halfline p and
A50:  r in L~f by XBOOLE_0:3;
      reconsider r as Element of TOP-REAL 2 by A49;
      r in west_halfline p /\ L~f by A49,A50,XBOOLE_0:def 4;
      then r`1 = W-bound L~f by JORDAN1A:85,PSCOMP_1:34;
      then r in W-most L~f by A50,SPRECT_2:12;
      then (W-min L~f)`2 <= r`2 by PSCOMP_1:31;
      hence contradiction by A3,A48,A49,TOPREAL1:def 13;
    end;
  end;
  GoB f = G by JORDAN1H:44;
  then p in right_cell(f,k) by A23,A14,A31,JORDAN1H:23;
  hence thesis by A6,Th5;
end;
