reserve p,p1,p2,p3,q for Point of TOP-REAL 2;

theorem Th6:
  for P being compact non empty Subset of TOP-REAL 2, q1,q2 being
Point of TOP-REAL 2 st P is being_simple_closed_curve & LE q1,q2,P holds q1 in
  Segment(q1,q2,P) & q2 in Segment(q1,q2,P)
proof
  let P be compact non empty Subset of TOP-REAL 2, q1,q2 be Point of TOP-REAL
  2;
  assume that
A1: P is being_simple_closed_curve and
A2: LE q1,q2,P;
  hereby
    per cases;
    suppose
A3:   q2<>W-min(P);
      q1 in P by A1,A2,Th5;
      then LE q1,q1,P by A1,JORDAN6:56;
      then q1 in {p: LE q1,p,P & LE p,q2,P} by A2;
      hence q1 in Segment(q1,q2,P) by A3,Def1;
    end;
    suppose
A4:   q2=W-min(P);
      q1 in P by A1,A2,Th5;
      then LE q1,q1,P by A1,JORDAN6:56;
      then q1 in {p1: LE q1,p1,P or q1 in P & p1=W-min(P)};
      hence q1 in Segment(q1,q2,P) by A4,Def1;
    end;
  end;
  per cases;
  suppose
A5: q2<>W-min(P);
    q2 in P by A1,A2,Th5;
    then LE q2,q2,P by A1,JORDAN6:56;
    then q2 in {p: LE q1,p,P & LE p,q2,P} by A2;
    hence thesis by A5,Def1;
  end;
  suppose
A6: q2=W-min(P);
    q2 in {p1: LE q1,p1,P or q1 in P & p1=W-min(P)} by A2;
    hence thesis by A6,Def1;
  end;
end;
