reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th6:
  card Permutations n = n!
proof
  set P = Permutations(n);
  reconsider N=n as Element of NAT by ORDINAL1:def 12;
  set X=finSeg N;
  set PER={F where F is Function of X,X:F is Permutation of X};
A1: P c= PER
  proof
    let x be object;
    assume x in P;
    then x is Permutation of X by MATRIX_1:def 12;
    hence thesis;
  end;
  PER c= P
  proof
    let x be object;
    assume x in PER;
    then ex F be Function of X,X st x=F & F is Permutation of X;
    hence thesis by MATRIX_1:def 12;
  end;
  then P=PER by A1,XBOOLE_0:def 10;
  hence card P = card X! by CARD_FIN:8
    .= n! by FINSEQ_1:57;
end;
