
theorem Th6:
  for S being lower-bounded non empty Poset for T being non empty
  Poset for f being monotone Function of S,T holds Image f is lower-bounded
proof
  let S be lower-bounded non empty Poset;
  let T be non empty Poset;
  let f be monotone Function of S,T;
  thus Image f is lower-bounded
  proof
    consider x being Element of S such that
A1: x is_<=_than the carrier of S by YELLOW_0:def 4;
    dom f = the carrier of S by FUNCT_2:def 1;
    then f.x in rng f by FUNCT_1:def 3;
    then reconsider fx = f.x as Element of Image f by YELLOW_0:def 15;
    take fx;
    let b be Element of Image f;
    b in the carrier of subrelstr (rng f);
    then b in rng f by YELLOW_0:def 15;
    then consider c be object such that
A2: c in dom f and
A3: f.c = b by FUNCT_1:def 3;
A4: the carrier of Image f c= the carrier of T by YELLOW_0:def 13;
    assume b in the carrier of Image f;
    reconsider b1 = b as Element of T by A4;
    reconsider c as Element of S by A2;
    x <= c by A1;
    then f.x <= b1 by A3,ORDERS_3:def 5;
    hence fx <= b by YELLOW_0:60;
  end;
end;
