reserve X for non empty set;
reserve e for set;
reserve x for Element of X;
reserve f,g for PartFunc of X,ExtREAL;
reserve S for SigmaField of X;
reserve F for Function of RAT,S;
reserve p,q for Rational;
reserve r for Real;
reserve n,m for Nat;
reserve A,B for Element of S;

theorem Th6:
  for S,f,g,A st f is A-measurable & g is A-measurable holds
  ex F being Function of RAT,S st for p being Rational holds
  F.p = (A /\ less_dom(f, p)) /\ (A /\ less_dom(g, (r-p)))
proof
  let S,f,g,A;
  assume
A1: f is A-measurable & g is A-measurable;
  defpred P[object,object] means ex p st p = $1 &
  $2 = (A /\ less_dom(f, p)) /\ (A /\ less_dom(g, (r-p)));
A2: for x1 being object st x1 in RAT
ex y1 being object st y1 in S & P[x1,y1]
  proof
    let x1 be object;
    assume x1 in RAT;
    then consider p such that
A3: p = x1;
    A4: A
 /\ less_dom(f, p) in S & A /\ less_dom(g, (r-p)) in S by A1;
    take (A /\ less_dom(f, p)) /\ (A /\ less_dom(g, (r-p)));
    thus thesis by A3,A4,FINSUB_1:def 2;
  end;
  consider G being Function of RAT,S such that
A5: for x1 being object st x1 in RAT holds P[x1,G.x1] from FUNCT_2:sch 1(A2);
A6: for p being Rational holds
  G.p = (A /\ less_dom(f, p)) /\ (A /\ less_dom(g, (r-p)))
  proof
    let p be Rational;
 p in RAT by RAT_1:def 2;
then  ex q st q = p & G.p = (A /\ less_dom(f, q)) /\ (A /\
    less_dom(g, (r-q))) by A5;
    hence thesis;
  end;
  take G;
  thus thesis by A6;
end;
