reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th6:
  for R be irreflexive symmetric RelStr st card (the carrier of R) = 2
 ex a,b be object st the carrier of R = {a,b} & (the InternalRel of R = {
  [a,b],[b,a]} or the InternalRel of R = {})
proof
  let R be irreflexive symmetric RelStr;
  set Q = the InternalRel of R;
  assume
A1: card (the carrier of R) = 2;
  then reconsider X = the carrier of R as finite set;
  consider a,b be object such that
A2: a <> b and
A3: X = {a,b} by A1,CARD_2:60;
A4: the InternalRel of R c= {[a,b],[b,a]}
  proof
    let x be object;
    assume
A5: x in the InternalRel of R;
    then consider x1,x2 be object such that
A6: x = [x1,x2] and
A7: x1 in X and
A8: x2 in X by RELSET_1:2;
A9: x1 = a or x1 = b by A3,A7,TARSKI:def 2;
    per cases by A3,A6,A8,A9,TARSKI:def 2;
    suppose
A10:  x = [a,a];
      a in the carrier of R by A3,TARSKI:def 2;
      hence thesis by A5,A10,NECKLACE:def 5;
    end;
    suppose
      x = [a,b];
      hence thesis by TARSKI:def 2;
    end;
    suppose
      x = [b,a];
      hence thesis by TARSKI:def 2;
    end;
    suppose
A11:  x = [b,b];
      b in the carrier of R by A3,TARSKI:def 2;
      hence thesis by A5,A11,NECKLACE:def 5;
    end;
  end;
  per cases by A4,ZFMISC_1:36;
  suppose
    Q = {};
    hence thesis by A3;
  end;
  suppose
A12: Q = {[a,b]};
A13: a in X & b in X by A3,TARSKI:def 2;
A14: Q is_symmetric_in X by NECKLACE:def 3;
    [a,b] in Q by A12,TARSKI:def 1;
    then [b,a] in Q by A13,A14;
    then [b,a] = [a,b] by A12,TARSKI:def 1;
    hence thesis by A2,XTUPLE_0:1;
  end;
  suppose
A15: Q = {[b,a]};
A16: a in X & b in X by A3,TARSKI:def 2;
A17: Q is_symmetric_in X by NECKLACE:def 3;
    [b,a] in Q by A15,TARSKI:def 1;
    then [a,b] in Q by A16,A17;
    then [b,a] = [a,b] by A15,TARSKI:def 1;
    hence thesis by A2,XTUPLE_0:1;
  end;
  suppose
    Q = {[a,b],[b,a]};
    hence thesis by A3;
  end;
end;
