
theorem Th6:
  for a being Integer st not 3 divides a holds a|^3 mod 9 = 1 or a|^3 mod 9 = 8
  proof
    let a be Integer;
    assume not 3 divides a;
    then a mod 3 <> 0 by INT_1:62;
    then a mod 3 > 0 & a mod 3 < 3 by INT_1:57,58;
    then A1: a mod 3 > 0 & a mod 3 in Segm 3 by NAT_1:44;
    set d = a div 3;
    A2:
    now
      assume a mod 3 = 1;
      then a = d*3 + 1 by INT_1:59;
      then a|^3 = (3*d)|^3+3*(3*d)|^2+3*(3*d)+1 by SERIES_2:2
      .= (3|^3*d|^3)+3*(3*d)|^2+3*(3*d)+1 by NEWTON:7
      .= ((3*3*3)*d|^3)+3*(3*d)|^2+3*(3*d)+1 by POLYEQ_3:27
      .= ((3*3*3)*d|^3)+3*((3|^2*d|^2))+3*(3*d)+1 by NEWTON:7
      .= ((3*3*3)*d|^3)+3*((3*3)*d|^2)+3*(3*d)+1 by WSIERP_1:1
      .= 9*(3*d|^3+3*d|^2+d)+1;
      hence a|^3 mod 9 = ((9*(3*d|^3+3*d|^2+d) mod 9) + (1 mod 9)) mod 9
      by NAT_D:66
      .= (0 + (1 mod 9)) mod 9 by NAT_D:71
      .= 1 by NAT_D:63;
    end;
    A3:
    now
      assume a mod 3 = 2;
      then a = d*3 + 2 by INT_1:59;
      then a|^3 = (3*d)|^3+3*(3*d)|^2*2+3*2|^2*(3*d)+2|^3 by SERIES_4:2
      .= (3|^3*d|^3)+3*(3*d)|^2*2+3*2|^2*(3*d)+2|^3 by NEWTON:7
      .= ((3*3*3)*d|^3)+3*(3*d)|^2*2+3*2|^2*(3*d)+2|^3 by POLYEQ_3:27
      .= ((3*3*3)*d|^3)+3*(3|^2*d|^2)*2+3*2|^2*(3*d)+2|^3 by NEWTON:7
      .= ((3*3*3)*d|^3)+3*((3*3)*d|^2)*2+3*2|^2*(3*d)+2|^3 by WSIERP_1:1
      .= 9*(3*d|^3+3*d|^2*2+2|^2*d)+(2*2*2) by POLYEQ_3:27;
      hence a|^3 mod 9 = ((9*(3*d|^3+3*d|^2*2+2|^2*d)) mod 9 +
      ((2*2*2) mod 9)) mod 9 by NAT_D:66
      .= (0 + (8 mod 9)) mod 9 by NAT_D:71
      .= 8 by NAT_D:63;
    end;
    thus thesis by A2,A3,A1,ENUMSET1:def 1,CARD_1:51;
  end;
