reserve I for non empty set,
  J for ManySortedSet of I,
  S for non void non empty ManySortedSign,
  i for Element of I,
  c for set,
  A for MSAlgebra-Family of I,S,
  EqR for Equivalence_Relation of I,
  U0,U1,U2 for MSAlgebra over S,
  s for SortSymbol of S,
  o for OperSymbol of S,
  f for Function;

theorem
  (the Sorts of U0).s <> {} implies Constants(U0,s) = { const(o,U0)
  where o is Element of the carrier' of S : the_result_sort_of o = s &
  the_arity_of o = {} }
proof
  assume
A1: (the Sorts of U0).s <> {};
  thus Constants(U0,s) c= { const(o,U0) where o is Element of the carrier' of
S: the_result_sort_of o = s & the_arity_of o = {} }
  proof
    let x be object;
    assume
A2: x in Constants(U0,s);
    ex A being non empty set st A =(the Sorts of U0).s & Constants(U0,s) =
{ a where a is Element of A : ex o be OperSymbol of S st (the Arity of S).o =
{} & (the ResultSort of S).o = s & a in rng Den(o,U0)} by A1,MSUALG_2:def 3;
    then consider A being non empty set such that
    A =(the Sorts of U0).s and
A3: x in { a where a is Element of A : ex o be OperSymbol of S st (the
Arity of S).o = {} & (the ResultSort of S).o = s & a in rng Den(o,U0)} by A2;
    consider a be Element of A such that
A4: a = x and
A5: ex o be OperSymbol of S st (the Arity of S).o = {} & (the
    ResultSort of S).o = s & a in rng Den(o,U0) by A3;
    consider o1 be OperSymbol of S such that
A6: (the Arity of S).o1 = {} and
A7: (the ResultSort of S).o1 = s and
A8: a in rng Den(o1,U0) by A5;
A9: ex x1 be object st x1 in dom Den(o1,U0) & a = Den(o1,U0).x1 by A8,
FUNCT_1:def 3;
A10: the_result_sort_of o1 = s by A7,MSUALG_1:def 2;
A11: the_arity_of o1 = {} by A6,MSUALG_1:def 1;
    then Args(o1,U0) = {{}} by PRALG_2:4;
    then x = const(o1,U0) by A4,A9,TARSKI:def 1;
    hence thesis by A10,A11;
  end;
  let x be object;
  assume x in { const(o,U0) where o is Element of the carrier' of S :
  the_result_sort_of o = s & the_arity_of o = {} };
  then consider o being Element of the carrier' of S such that
A12: x = const(o,U0) and
A13: the_result_sort_of o = s and
A14: the_arity_of o = {};
  o in the carrier' of S;
  then
A15: o in dom (the ResultSort of S) by FUNCT_2:def 1;
A16: Result(o,U0) = ((the Sorts of U0) * the ResultSort of S).o by
MSUALG_1:def 5
    .= (the Sorts of U0).((the ResultSort of S).o) by A15,FUNCT_1:13
    .= (the Sorts of U0).s by A13,MSUALG_1:def 2;
  thus x in Constants(U0,s)
  proof
A17: ex o be OperSymbol of S st (the Arity of S).o = {} & (the ResultSort
    of S).o = s & x in rng Den(o,U0)
    proof
      take o;
      Args(o,U0) = dom Den(o,U0) & Args(o,U0) = {{}} by A1,A14,A16,
FUNCT_2:def 1,PRALG_2:4;
      then {} in dom Den(o,U0) by TARSKI:def 1;
      hence thesis by A12,A13,A14,FUNCT_1:def 3,MSUALG_1:def 1,def 2;
    end;
    consider A being non empty set such that
A18: A =(the Sorts of U0).s and
A19: Constants(U0,s) = { a where a is Element of A : ex o be
OperSymbol of S st (the Arity of S).o = {} & (the ResultSort of S).o = s & a in
    rng Den(o,U0)} by A1,MSUALG_2:def 3;
    x is Element of A by A12,A14,A16,A18,Th5;
    hence thesis by A19,A17;
  end;
end;
