reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;

theorem Th6:
  for f being Function of Omega,REAL
  st f is Real-Valued-Random-Variable of Sigma holds
  { x where x is Element of Borel_Sets : f"x is Element of Sigma }
  = Borel_Sets
  proof
    let f be Function of Omega,REAL;
    assume
    A1: f is Real-Valued-Random-Variable of Sigma;
    set B
    = { x where x is Element of Borel_Sets : f"x is Element of Sigma };
    now let z be object;
      assume A2: z in Family_of_halflines;
      Family_of_halflines c= sigma(Family_of_halflines) by PROB_1:def 9;
      then reconsider y = z as Element of Borel_Sets by A2;
      consider r be Element of REAL such that
      A3: y = halfline(r) by A2;
      f"y is Element of Sigma by A1,Th4,A3;
      hence z in B;
    end; then
    A4: Family_of_halflines c= B;
    B is SigmaField of REAL by Th5,A1; then
    A5: Borel_Sets c= B by A4,PROB_1:def 9;
    now let x be object;
      assume x in B; then
      ex z be Element of Borel_Sets st z=x & f"z is Element of Sigma;
      hence x in Borel_Sets;
    end;
    then B c= Borel_Sets;
    hence B= Borel_Sets by A5;
  end;
