reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem
  for V be vector-distributive scalar-distributive scalar-associative
  scalar-unitalnon empty RLSStruct
    for A be Subset of V holds Int A = A iff A is trivial
  proof
    let V be vector-distributive scalar-distributive scalar-associative
    scalar-unitalnon empty RLSStruct;
    let A be Subset of V;
    per cases;
    suppose A is empty;
      hence thesis;
    end;
    suppose A1: A is non empty;
      hereby assume A2: Int A=A;
        now let x,y be object;
          assume that
          A3: x in A and
          A4: y in A;
          A\{x}c=A & A\{x}<>A by A3,ZFMISC_1:56;
          then A\{x}c=conv(A\{x}) & A\{x}c<A by RLAFFIN1:2;
          then not y in A\{x} by A2,Def1;
          hence x=y by A4,ZFMISC_1:56;
        end;
        hence A is trivial by ZFMISC_1:def 10;
      end;
      assume A is trivial;
      then consider v be Element of V such that
      A5: A={v} by A1,SUBSET_1:47;
      A6: not ex B be Subset of V st B c<A & v in conv B
      proof
        let B be Subset of V;
        assume A7: B c<A;
        B is empty by A5,A7,ZFMISC_1:33;
        hence thesis;
      end;
      A8: conv A=A by A5,RLAFFIN1:1;
      then A9: Int A c=A by Lm2;
      v in A by A5,TARSKI:def 1;
      then v in Int A by A6,A8,Def1;
      hence thesis by A5,A9,ZFMISC_1:33;
    end;
  end;
