reserve V,X,Y for RealLinearSpace;
reserve u,u1,u2,v,v1,v2 for VECTOR of V;
reserve a for Real;
reserve V1,V2,V3 for Subset of V;
reserve x for object;

theorem
  V1 is linearly-closed & V2 is linearly-closed & V3 = {v + u : v in V1
  & u in V2} implies V3 is linearly-closed
proof
  assume that
A1: V1 is linearly-closed & V2 is linearly-closed and
A2: V3 = {v + u : v in V1 & u in V2};
  thus for v,u st v in V3 & u in V3 holds v + u in V3
  proof
    let v,u;
    assume that
A3: v in V3 and
A4: u in V3;
    consider v2,v1 such that
A5: v = v1 + v2 and
A6: v1 in V1 & v2 in V2 by A2,A3;
    consider u2,u1 such that
A7: u = u1 + u2 and
A8: u1 in V1 & u2 in V2 by A2,A4;
A9: v + u = ((v1 + v2) + u1) + u2 by A5,A7,RLVECT_1:def 3
      .= ((v1 + u1) + v2) + u2 by RLVECT_1:def 3
      .= (v1 + u1) + (v2 + u2) by RLVECT_1:def 3;
    v1 + u1 in V1 & v2 + u2 in V2 by A1,A6,A8;
    hence thesis by A2,A9;
  end;
  let a,v;
  assume v in V3;
  then consider v2,v1 such that
A10: v = v1 + v2 and
A11: v1 in V1 & v2 in V2 by A2;
A12: a * v = a * v1 + a * v2 by A10,RLVECT_1:def 5;
  a * v1 in V1 & a * v2 in V2 by A1,A11;
  hence thesis by A2,A12;
end;
