
theorem Th5:
for V being RealUnitarySpace,
    u be Point of V,
    n be Nat,
    x be FinSequence of V
     st 1 <= n & n <= len x &
      for i be Nat st 1 <= i & i <= len x & n <> i
        holds u .|. (x/.i) = 0
   holds u .|. (Sum x) = u .|. (x/.n)
proof
let V be RealUnitarySpace,
    u be Point of V,
    n be Nat;
defpred P[Nat] means
  for x be FinSequence of V
     st $1 = len x & 1<=n & n <= len x &
      for i be Nat st 1<=i & i <= len x & n <> i
        holds u .|. (x/.i) = 0
   holds u .|. (Sum x) = u .|. (x/.n);
A1:P[0];
A2:for k be Nat st P[k] holds P[k+1]
proof
  let k be Nat;
  assume A3: P[k];
  let x be FinSequence of V;
    assume A4: k+1 = len x & 1<=n & n <= len x &
      for i be Nat st 1<=i & i <= len x & n <> i
        holds u .|. (x/.i) = 0; then
    A5: n in dom x by FINSEQ_3:25;
defpred P1[Nat,object] means $2 = u .|. (x/.$1);
A6: for k being Nat st k in Seg len x holds
   ex v being Element of REAL st P1[k,v];
consider r being FinSequence of REAL such that
A7: dom r = Seg len x &
 for k being Nat st k in Seg len x holds
     P1[k,r . k] from FINSEQ_1:sch 5(A6);
  A8: len x = len r
     & for i be Nat st 1<=i & i <= len x
            holds r.i = u .|. (x/.i)
   by A7,FINSEQ_1:def 3,FINSEQ_1:1;
set x1=x | k;
set r1=r | k;
A11: len x1 = k & len r1 = k by A4,A8,FINSEQ_1:59,NAT_1:11;
A24: dom r1 = Seg len r1 by FINSEQ_1:def 3;
per cases;
    suppose A25:n = k+1;
    for i be object st i in dom r1 holds r1.i = 0
    proof
       let t be object;
       assume A27: t in dom r1; then
       reconsider i=t as Nat;
       A28: 1<=i & i <= len r1 by A27,A24,FINSEQ_1:1;
       A29: i <= k by A11,A27,A24,FINSEQ_1:1; then
       A31: i <= len x by A4,NAT_1:13;
       i <> n by NAT_1:13,A25,A29; then
       u .|. (x/.i) = 0 by A4,A28,A31; then
       r.i = 0 by A28,A31, A7,FINSEQ_1:1;
       hence r1.t = 0 by A27,A24,FUNCT_1:49,A11;
    end; then
    r1 = (len r1 |-> 0) by FINSEQ_1:def 3; then
A32: Sum r1 = 0 by RVSUM_1:81;
    r = r1 ^ <*(r . (k + 1))*> by FINSEQ_3:55,A8,A4
     .= r1 ^ <*u .|. (x/.n) *> by A25,A4,A7,FINSEQ_1:1; then
W1: Sum r = 0 + u .|. (x/.n) by A32,RVSUM_1:74;
    u .|. (Sum x) = Sum (u .|. x) by Th4;
       hence u .|. (Sum x) = u .|. (x/.n) by A8,W1,DefSK;
    end;
    suppose A33: n <> k+1;
      A34: k= len x1 & 1<=n & n <= len x1 &
      for i be Nat st 1<=i & i <= len x1 & n <> i
        holds u .|. (x1/.i) = 0
      proof
       n < k + 1 by A33,A4,XXREAL_0:1;
       hence k= len x1 & 1<=n & n <= len x1 by NAT_1:13,A4,A11;
       let i be Nat;
       assume A35: 1<=i & i <=len x1 & n <> i;
       k <= k+1 by NAT_1:11; then
       A36:i <= len x by A4,A11,A35,XXREAL_0:2;
       A38: i in Seg k by A35,A11;
       A39: i in dom x1 by A35,FINSEQ_3:25;
       i in dom x by A35,A36,FINSEQ_3:25; then
       x/.i = x.i by PARTFUN1:def 6
            .= x1.i by FUNCT_1:49,A38
            .= x1/.i by PARTFUN1:def 6,A39;
       hence thesis by A4,A35,A36;
      end; then
      A40: n in Seg k; then
      n in dom x1 by A11,FINSEQ_1:def 3; then
      A41:x1/.n =x1.n by PARTFUN1:def 6
                .=x.n by FUNCT_1:49,A40
                .=x/.n by PARTFUN1:def 6,A5;
      A43: len x = len x1 + 1 by A4,FINSEQ_1:59,NAT_1:11;
      A44: dom x1 = Seg k by A11,FINSEQ_1:def 3;
A0:   1 <= k+1 by NAT_1:11; then
      k+1 in dom x by A4,FINSEQ_3:25; then
      A45a:x/.(k+1) = x.(len x) by A4,PARTFUN1:def 6;
      A46: u .|. (x/.(k+1)) = 0 by A33,A4,A0;
      thus u .|. (Sum x)
            = u .|. (Sum x1 + x/.(k+1)) by A45a,A43,A44,RLVECT_1:38
            .= u .|. (Sum x1) + u .|.(x/.(k+1)) by BHSP_1:2
            .= u .|. (x/.n) by A46,A41,A3,A34;
    end;
end;
for k be Nat holds P[k] from NAT_1:sch 2(A1,A2);
hence thesis;
end;
