reserve y,w for set;
reserve T for non empty TopSpace;

theorem Th6:
  for T,T1 being non empty TopSpace,f being continuous Function of
T,T1 holds T1 is T_1 implies for w for x being Element of T holds w = EqClass(x
  ,(Intersection Closed_Partitions T)) implies w c= f"{f.x}
proof
  let T,T1 be non empty TopSpace;
  let f be continuous Function of T,T1;
  assume
A1: T1 is T_1;
  then reconsider
  fz = {f"{z} where z is Element of T1 : z in rng f} as a_partition
  of the carrier of T by Th5;
  let w be set;
  let x be Element of T;
  for A being Subset of T st A in fz holds A is closed by A1,Th5;
  then fz is closed by TOPS_2:def 2;
  then fz in {B where B is a_partition of the carrier of T : B is closed};
  then
A2: EqClass(x,fz) in {EqClass(x,S) where S is a_partition of the carrier of
T: S in Closed_Partitions T};
  assume
A3: w = EqClass(x,(Intersection Closed_Partitions T));
A4: dom f = the carrier of T by FUNCT_2:def 1;
A5: f"{f.x} = EqClass(x,fz)
  proof
    reconsider fx = f.x as Element of T1;
    f.x in rng f by A4,FUNCT_1:def 3;
    then
A6: f"{fx} in fz;
    f.x in {f.x} by TARSKI:def 1;
    then x in f"{f.x} by A4,FUNCT_1:def 7;
    hence thesis by A6,EQREL_1:def 6;
  end;
  let y be object;
A7: EqClass(x,(Intersection Closed_Partitions T)) = meet{EqClass(x,S) where
S is a_partition of the carrier of T : S in Closed_Partitions T} by
EQREL_1:def 8;
  assume y in w;
  hence thesis by A3,A2,A5,A7,SETFAM_1:def 1;
end;
