reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th6:
  for N being symmetric non empty MetrStruct, S2 being sequence of N
   holds S2 is Cauchy iff for r st r>0 ex p st for
         n,k st p<=n holds dist(S2.(n+k),S2.n)<r
proof let N be symmetric non empty MetrStruct, S2 be sequence of N;
  thus S2 is Cauchy implies for r st r>0 ex p st for n,k st p<=n holds dist(S2
  .(n+k),S2.n)<r
  proof
    assume
A1: S2 is Cauchy;
    let r;
    assume 0<r;
    then consider p such that
A2: for n,m st p<=n & p<=m holds dist(S2.n,S2.m)<r by A1;
    take p;
    let n,k be Nat such that
A3: p<=n;
    n<=n+k by NAT_1:11;
    then p<=n+k by A3,XXREAL_0:2;
    hence thesis by A2,A3;
  end;
  assume
A4: for r st r>0 ex p st for n,k st p<=n holds dist(S2.(n+k),S2.n)<r;
  let r;
  assume 0<r;
  then consider p such that
A5: for n,k st p<=n holds dist(S2.(n+k),S2.n)<r by A4;
  take p;
  let n,m such that
A6: p<=n and
A7: p<=m;
  per cases;
  suppose
    n<=m;
    then consider k be Nat such that
A8: m=n+k by NAT_1:10;
    reconsider m9=m,n9=n,k as Nat;
    m = n+k by A8;
    then dist(S2.m9,S2.n9)<r by A5,A6;
    hence thesis;
  end;
  suppose
    m<=n;
    then consider k be Nat such that
A9: n=m+k by NAT_1:10;
    reconsider k as Nat;
    n = m+k by A9;
    hence thesis by A5,A7;
  end;
end;
