reserve X for set,
        D for a_partition of X,
        TG for non empty TopologicalGroup;
reserve A for Subset of X;

theorem Th2: :: EQREL_1:43 generalized
  for P being Subset of D holds union (D \ P) = union D \ union P
  proof
    let P be Subset of D;
    thus union (D \ P) c= union D \ union P
    proof
      let x be object;
      assume x in union (D\ P); then
      consider y be set such that
A2:   x in y and
A3:   y in D \ P by TARSKI:def 4;
      y in D & not y in P by A3,XBOOLE_0:def 5; then
A4:   x in union D by A2,TARSKI:def 4;
      not x in union P
      proof
        assume x in union P;
        then consider z be set such that
A5:     x in z and
A6:     z in P by TARSKI:def 4;
        z in D & y in D by A3,A6,XBOOLE_0:def 5;
        then y = z or y misses z by EQREL_1:def 4;
        hence thesis by A2,A5,A6,A3,XBOOLE_0:def 4,XBOOLE_0:def 5;
      end;
      hence thesis by A4,XBOOLE_0:def 5;
    end;
      let x be object;
      assume x in union D \ union P; then
A7:   x in union D & not x in union P by XBOOLE_0:def 5;
      then consider y be set such that
A8:   x in y and
A9:   y in D by TARSKI:def 4;
      y in D \ P
      proof
        assume not y in D \ P;
        then y in P or not y in D by XBOOLE_0:def 5;
        hence thesis by A7,A8,A9,TARSKI:def 4;
      end;
      hence thesis by A8,TARSKI:def 4;
  end;
