
theorem Th6:
  for S, T being non empty TopSpace st S is injective & S, T
  are_homeomorphic holds T is injective
proof
  let S, T be non empty TopSpace such that
A1: S is injective and
A2: S, T are_homeomorphic;
  consider p being Function of S,T such that
A3: p is being_homeomorphism by A2;
  let X be non empty TopSpace, f be Function of X, T;
  assume
A4: f is continuous;
  let Y be non empty TopSpace;
  assume
A5: X is SubSpace of Y;
  then
A6: [#]X c= [#]Y by PRE_TOPC:def 4;
A7: p is one-to-one by A3;
  set F = p"*f;
  p" is continuous by A3;
  then consider G being Function of Y,S such that
A8: G is continuous and
A9: G|(the carrier of X) = F by A1,A4,A5;
  take g = p*G;
A10: rng p = [#]T by A3;
A11: for x being object st x in dom f holds g.x = f.x
  proof
    let x be object;
    assume
A12: x in dom f;
    then
A13: f.x in rng f by FUNCT_1:def 3;
    then f.x in the carrier of T;
    then
A14: f.x in dom (p") by FUNCT_2:def 1;
    x in the carrier of X by A12;
    then x in the carrier of Y by A6;
    then x in dom G by FUNCT_2:def 1;
    hence g.x = p.(G.x) by FUNCT_1:13
      .= p.((p"*f).x) by A9,A12,FUNCT_1:49
      .= p.(p".(f.x)) by A12,FUNCT_1:13
      .= (p*p").(f.x) by A14,FUNCT_1:13
      .= (id the carrier of T).(f.x) by A10,A7,TOPS_2:52
      .= f.x by A13,FUNCT_1:17;
  end;
  p is continuous by A3;
  hence g is continuous by A8;
  dom f = the carrier of X by FUNCT_2:def 1
    .= (the carrier of Y) /\ (the carrier of X) by A6,XBOOLE_1:28
    .= dom g /\ (the carrier of X) by FUNCT_2:def 1;
  hence thesis by A11,FUNCT_1:46;
end;
