 reserve x, y, y1, y2 for set;
 reserve V for Z_Module;
 reserve u, v, w for Vector of V;
 reserve F, G, H, I for FinSequence of V;
 reserve W, W1, W2, W3 for Submodule of V;
 reserve KL1, KL2 for Linear_Combination of V;
 reserve X for Subset of V;

theorem Th6:
  for L being Linear_Combination of V for F being FinSequence of V st
  Carrier(L) misses rng F holds Sum(L (#) F) = 0.V :::by VECTSP_9:2;
  proof
    let L be Linear_Combination of V;
    defpred P[FinSequence] means for G being FinSequence of V st
    G = $1 holds Carrier(L) misses rng G implies Sum(L (#) G) = 0.V;
    A1: for p being FinSequence, x being object st P[p] holds P[p^<*x*>]
    proof
      let p be FinSequence, x be object such that
      A2: P[p];
      let G be FinSequence of V;
      assume A3: G = p^<*x*>;
      then reconsider p, x9= <*x*> as FinSequence of V by FINSEQ_1:36;
      x in {x} by TARSKI:def 1;
      then
      A4: x in rng x9 by FINSEQ_1:38;
      reconsider x as Vector of V by A4;
      assume Carrier(L) misses rng G;
      then
      A5: {} = Carrier(L) /\ rng G by XBOOLE_0:def 7
      .= Carrier(L) /\ (rng p \/ rng<*x*>) by A3,FINSEQ_1:31
      .= Carrier(L) /\ (rng p \/ {x}) by FINSEQ_1:38
      .= Carrier(L) /\ rng p \/ Carrier(L) /\ {x} by XBOOLE_1:23;
      then Carrier(L) /\ rng p = {};
      then
      A6: Sum(L (#) p) = 0.V by A2,XBOOLE_0:def 7;
      A7: Carrier(L) /\ {x} = {} by A5;
      now
        A8: x in {x} by TARSKI:def 1;
        assume x in Carrier(L);
        hence contradiction by A7,A8,XBOOLE_0:def 4;
      end;
      then
      A9: L.x = 0;
      Sum(L (#) G) = Sum((L (#) p) ^ (L (#) x9)) by A3,ZMODUL02:51
      .= Sum(L (#) p) + Sum(L (#) x9) by RLVECT_1:41
      .= 0.V + Sum(<* L.x * x *>) by A6,ZMODUL02:15
      .= Sum(<* L.x * x *>) by RLVECT_1:4
      .= 0.INT.Ring * x by A9,RLVECT_1:44
      .= 0.V by ZMODUL01:1;
      hence thesis;
    end;
    A10: P[{}]
    proof
      let G be FinSequence of V;
      assume G = {};
      then
      A11: L (#) G = <*>(the carrier of V) by ZMODUL02:14;
      assume Carrier(L) misses rng G;
      thus thesis by A11,RLVECT_1:43;
    end;
    A12: for p being FinSequence holds P[p] from FINSEQ_1:sch 3(A10, A1);
    let F be FinSequence of V;
    assume Carrier(L) misses rng F;
    hence thesis by A12;
  end;
