reserve
  X for non empty set,
  FX for Filter of X,
  SFX for Subset-Family of X;

theorem
  for X be non empty set, B be non empty Subset of BoolePoset X holds
  (for x,y be Element of B ex z be Element of B st z c= x/\y)
  iff B is filtered
  proof
    let X be non empty set,
    B be non empty Subset of BoolePoset X;
    hereby
      assume
A1:   (for x,y be Element of B ex z be Element of B st z c= x/\y);
      for x,y being Element of BoolePoset X st x in B & y in B
      ex z being Element of BoolePoset X st z in B & z<=x & z<=y
      proof
        let x,y be Element of BoolePoset X such that
A2:     x in B & y in B;
        reconsider x,y as Element of B by A2;
        consider z0 be Element of B such that
A3:     z0 c= x/\y by A1;
        reconsider z0 as Element of BoolePoset X;
        take z0;
        x/\y c= x & x/\y c=y by XBOOLE_1:17;
        then z0 c= x & z0 c= y by A3;
        hence thesis by YELLOW_1:2;
      end;
      hence B is filtered;
    end;
    assume
A4: B is filtered;
    for x,y be Element of B ex z be Element of B st z c= x/\y
    proof
      let x,y be Element of B;
      consider z0 be Element of BoolePoset X such that
A5:   z0 in B and
A6:   z0 <= x and
A7:   z0 <= y by A4;
A8:   z0 c= x & z0 c= y by A6,A7,YELLOW_1:2;
      reconsider z0 as Element of B by A5;
      take z0;
      thus thesis by A8,XBOOLE_1:19;
    end;
    hence thesis;
  end;
