reserve m for Cardinal,
  A,B,C for Ordinal,
  x,y,z,X,Y,Z,W for set,
  f for Function;
reserve f,g for Function,
  L for Sequence,
  F for Cardinal-Function;
reserve U1,U2,U for Universe;
reserve u,v for Element of U;

theorem Th70:
  A in B iff UNIVERSE A in UNIVERSE B
proof
  defpred P[Ordinal] means for A st A in $1 holds UNIVERSE A in UNIVERSE $1;
A1: for B st P[B] holds P[succ B]
  proof
    let B such that
A2: P[B];
    let A;
    assume
A3: A in succ B;
    A c< B iff A c= B & A <> B;
    then A in B or A = B by A3,ORDINAL1:11,22;
    then
A4: UNIVERSE A in UNIVERSE B or UNIVERSE A = UNIVERSE B by A2;
    UNIVERSE succ B = Tarski-Class UNIVERSE B by Lm6;
    then UNIVERSE B in UNIVERSE succ B by CLASSES1:2;
    hence thesis by A4,ORDINAL1:10;
  end;
A5: for A st A <> 0 & A is limit_ordinal & for B st B in A holds P[B]
  holds P[A]
  proof
    let B;
    assume that
A6: B <> 0 and
A7: B is limit_ordinal and
    for C st C in B for A st A in C holds UNIVERSE A in UNIVERSE C;
    let A;
    consider L such that
A8: dom L = B & for C st C in B holds L.C = u(C) from ORDINAL2:sch 2;
    assume A in B;
    then
A9: succ A in B by A7,ORDINAL1:28;
    then L.succ A = UNIVERSE succ A by A8;
    then UNIVERSE succ A in rng L by A9,A8,FUNCT_1:def 3;
    then
A10: UNIVERSE succ A c= union rng L by ZFMISC_1:74;
    UNIVERSE B = Universe_closure Union L by A6,A7,A8,Lm6
      .= Universe_closure union rng L by CARD_3:def 4;
    then union rng L c= UNIVERSE B by Def4;
    then
A11: UNIVERSE succ A c= UNIVERSE B by A10;
A12: UNIVERSE A in Tarski-Class UNIVERSE A by CLASSES1:2;
    UNIVERSE succ A = Tarski-Class UNIVERSE A by Lm6;
    hence thesis by A12,A11;
  end;
A13: P[0];
A14: for B holds P[B] from ORDINAL2:sch 1(A13,A1,A5);
  hence A in B implies UNIVERSE A in UNIVERSE B;
  assume that
A15: UNIVERSE A in UNIVERSE B and
A16: not A in B;
  B in A or B = A by A16,ORDINAL1:16;
  hence contradiction by A14,A15;
end;
