reserve U for Universe;
reserve x for Element of U;
reserve U1,U2 for Universe;

theorem Th72:
  for C,D being Category st C is U-element & D is U-element holds
  Functors(C,D) is U-element
  proof
    let C,D be Category;
    assume that
A1: C is U-element and
A2: D is U-element;
    set E = Functors(C,D);
    reconsider cC  = the carrier  of C,
               c9C = the carrier' of C,
               cD  = the carrier  of D,
               c9D = the carrier' of D as Element of U by A1,A2;
    now
      the carrier of E = Funct(C,D) by NATTRA_1:def 17;
      then
A3:   the carrier of E c= bool [:c9C,c9D:] by Th68;
      hence the carrier of E is Element of U by CLASSES4:13;
      reconsider cE = the carrier of E as Element of U by A3,CLASSES4:13;
      (the carrier' of E) = NatTrans(C,D) by NATTRA_1:def 17;
      then
A4:   (the carrier' of E)
        c= [: [:bool [:c9C,c9D:],bool [:c9C,c9D:]:],bool [:cC,c9D:] :]
        by Th69;
      hence (the carrier' of E) is Element of U by CLASSES4:13;
      reconsider c9E = the carrier' of E as Element of U by A4,CLASSES4:13;
A5:   (the Source of E) in Funcs(c9E,cE) by FUNCT_2:8;
A6:   Funcs(c9E, cE) is Element of U & U is axiom_GU1 & U is axiom_GU3;
      hence the Source of E is Element of U by A5;
      (the Target of E) in Funcs(c9E,cE) by FUNCT_2:8;
      hence (the Target of E) is Element of U by A6;
      (the Comp of E) c= [:[:c9E,c9E:],c9E:];
      hence (the Comp of E) is Element of U by CLASSES4:13;
    end;
    hence thesis;
  end;
