
theorem MMLip2:
for f be Function of REAL,REAL, a,b,c,r,s be Real st
( b <> 0 & for x be Real holds f.x= max(r,min(s, c*(1-|.(x-a)/b.|))) )
holds f is Lipschitzian
proof
 let f be Function of REAL,REAL;
 let a,b,c,r,s be Real;
 assume A3: b <> 0;
 assume A1: for x be Real holds f.x= max(r,min(s, c*(1-|.(x-a)/b.|)));
 ex r being Real st
 ( 0 < r &
 ( for x1, x2 being Real st x1 in dom f & x2 in dom f holds
  |.((f . x1) - (f . x2)).| <= r * |.(x1 - x2).| ) )
 proof
 per cases;
 suppose C0: c = 0;
  take 1;
  for x1, x2 being Real st x1 in dom f & x2 in dom f holds
  |.((f . x1) - (f . x2)).| <= 1 * |.(x1 - x2).|
  proof
   let x1, x2 be Real;
   |.((f . x1) - (f . x2)).|
    = |.max(r,min(s, c*(1-|.(x1-a)/b.|)))-f.x2.| by A1
   .= |.max(r,min(s, 0*(1-|.(x1-a)/b.|)))-max(r,min(s, 0*(1-|.(x2-a)/b.|))).|
     by C0,A1
     .=0 by COMPLEX1:44;
     hence thesis by COMPLEX1:46;
  end;
  hence thesis;
 end;
 suppose A2: c <> 0;
  take 1/|.b.|*|.c.|;
  A5: |.c.|>0 & |.b.|>0 by A2,A3,COMPLEX1:47;
  for x1, x2 being Real st x1 in dom f & x2 in dom f holds
  |.((f . x1) - (f . x2)).| <= (1/|.b.|*|.c.|) * |.(x1 - x2).|
  proof
   let x1, x2 be Real;
   assume x1 in dom f & x2 in dom f;
   |.((f . x1) - (f . x2)).|
    = |.max(r,min(s, c*(1-|.(x1-a)/b.|)))-f.x2.| by A1
   .= |.max(r,min(s, c*(1-|.(x1-a)/b.|)))-max(r,min(s, c*(1-|.(x2-a)/b.|))).|
     by A1; then
   A9: |.((f . x1) - (f . x2)).|
   <= |.c*(1-|.(x1-a)/b.|)-c*(1-|.(x2-a)/b.|).| by LeMM01;
   |.(x1-a)/b-(x2-a)/b.| = |.((x1-a)-(x2-a))/b.| by XCMPLX_1:120
   .= |.(x1-x2).|/|.b.| by COMPLEX1:67; then
   |.|.(x1-a)/b.|-|.(x2-a)/b.|.|*|.c.|<= |.(x1-x2).|/|.b.| * |.c.| by
     XREAL_1:64,A5,COMPLEX1:64; then
   |.c.|* |.|.(x2-a)/b.|-|.(x1-a)/b.|.|<= |.(x1-x2).|/|.b.| * |.c.|
        by COMPLEX1:60; then
   |.c*(-|.(x1-a)/b.|+|.(x2-a)/b.|).|<= |.(x1-x2).|/|.b.| * |.c.|
        by COMPLEX1:65; then
   |.c*(1-|.(x1-a)/b.|)-c*(1-|.(x2-a)/b.|).|<= (1/|.b.|* |.c.|)*|.(x1-x2).|
        by XCMPLX_1:101;
   hence thesis by XXREAL_0:2,A9;
  end;
  hence thesis by A5;
 end;
 end;
 hence thesis;
end;
