reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem
  1 < len G & 1 <= j & j+1 < width G implies LSeg(1/2*(G*(1,j)+G*(1,j+1)
)-|[1,0]|,1/2*(G*(1,j+1)+G*(1,j+2))-|[1,0]|) c= Int cell(G,0,j) \/ Int cell(G,0
  ,j+1) \/ { G*(1,j+1)-|[1,0]| }
proof
  assume that
A1: 1 < len G and
A2: 1 <= j and
A3: j+1 < width G;
  set p1 = G*(1,j), p2 = G*(1,j+1), q3 = G*(1,j+2), r = (p2`2-p1`2)/(q3`2-p1`2
  );
A4: j+1+1 = j+(1+1);
  then
A5: j+2 >= 1 by NAT_1:11;
A6: j+(1+1) <= width G by A3,A4,NAT_1:13;
  set I1 = Int cell(G,0,j), I2 = Int cell(G,0,j+1);
A7: I1 \/ I2 \/ { p2-|[1,0]| } = I1 \/ (I2 \/ ({ p2-|[1,0]| } \/ { p2-|[1,0
  ]| })) by XBOOLE_1:4
    .= I1 \/ (I2 \/ { p2-|[1,0]| } \/ { p2-|[1,0]| }) by XBOOLE_1:4
    .= I1 \/ { p2-|[1,0]| } \/ (I2 \/ { p2-|[1,0]| }) by XBOOLE_1:4;
A8: LSeg(1/2*(p2+q3)-|[1,0]|,p2-|[1,0]|) c= I2 \/ { p2-|[1,0]| } by A3,A4,Th48,
NAT_1:11;
  j < j+1 by XREAL_1:29;
  then p1`2 < p2`2 by A1,A2,A3,GOBOARD5:4;
  then
A9: p2`2-p1`2 > 0 by XREAL_1:50;
A10: j+1 >= 1 by NAT_1:11;
  then
A11: p2`1 = G*(1,1)`1 by A1,A3,GOBOARD5:2
    .= q3`1 by A1,A6,A5,GOBOARD5:2;
  j <= j+1 by NAT_1:11;
  then
A12: j < width G by A3,XXREAL_0:2;
  then p1`1 = G*(1,1)`1 by A1,A2,GOBOARD5:2
    .= p2`1 by A1,A3,A10,GOBOARD5:2;
  then
A13: 1*p2`1 = (1-r)*p1`1+r*q3`1 by A11
    .= ((1-r)*p1)`1+r*q3`1 by Lm3
    .= ((1-r)*p1)`1+(r*q3)`1 by Lm3
    .= ((1-r)*p1+r*q3)`1 by Lm1;
  j+1 < j+2 by XREAL_1:6;
  then p2`2 < q3`2 by A1,A10,A6,GOBOARD5:4;
  then
A14: p2`2-p1`2 < q3`2-p1`2 by XREAL_1:9;
  then r*(q3`2-p1`2) = p2`2-p1`2 by A9,XCMPLX_1:87;
  then p2`2 = (1-r)*p1`2 +r*q3`2;
  then 1*p2`2 = ((1-r)*p1)`2+r*q3`2 by Lm3
    .= ((1-r)*p1)`2+(r*q3)`2 by Lm3
    .= ((1-r)*p1+(r*q3))`2 by Lm1;
  then
A15: (1-r)*p1+r*q3 = |[p2`1,p2`2]| by A13,EUCLID:53
    .= p2 by EUCLID:53;
  p2 = 1*p2 by RLVECT_1:def 8
    .= 1/2*p2+1/2*p2 by Lm7,RLVECT_1:def 6
    .= 1/2*(((1-r)+r)*p2) + 1/2*((1-r)*p1+r*q3) by A15,RLVECT_1:def 8
    .= 1/2*((1-r)*p2+r*p2) + 1/2*((1-r)*p1+r*q3) by RLVECT_1:def 6
    .= 1/2*((1-r)*p2)+1/2*(r*p2) + 1/2*((1-r)*p1+r*q3) by RLVECT_1:def 5
    .= 1/2*((1-r)*p2)+1/2*(r*p2) + (1/2*((1-r)*p1)+1/2*(r*q3)) by
RLVECT_1:def 5
    .= 1/2*((1-r)*p2)+(1/2*(r*p2) + (1/2*((1-r)*p1)+1/2*(r*q3))) by
RLVECT_1:def 3
    .= 1/2*((1-r)*p2)+(1/2*((1-r)*p1)+(1/2*(r*p2)+1/2*(r*q3))) by
RLVECT_1:def 3
    .= 1/2*((1-r)*p2)+1/2*((1-r)*p1)+(1/2*(r*p2)+1/2*(r*q3)) by RLVECT_1:def 3
    .= (1/2*((1-r)*p2)+1/2*((1-r)*p1))+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 3
    .= 1/2*((1-r)*p2+(1-r)*p1)+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 5
    .= 1/2*((1-r)*(p1+p2))+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 5
    .= 1/2*(1-r)*(p1+p2)+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 7
    .= 1/2*(1-r)*(p1+p2)+(1/2*(r*p2)+1/2*(r*q3)) by RLVECT_1:def 3
    .= 1/2*(1-r)*(p1+p2)+1/2*(r*p2+r*q3) by RLVECT_1:def 5
    .= 1/2*(1-r)*(p1+p2)+1/2*(r*(p2+q3)) by RLVECT_1:def 5;
  then
A16: p2 = (1-r)*(1/2*(p1+p2))+1/2*(r*(p2+q3)) by RLVECT_1:def 7
    .= (1-r)*(1/2*(p1+p2))+1/2*r*(p2+q3) by RLVECT_1:def 7
    .= (1-r)*((1/2)*(p1+p2))+r*((1/2)*(p2+q3)) by RLVECT_1:def 7;
A17: (1-r)*(1/2*(p1+p2)-|[1,0]|)+r*(1/2*(p2+q3)-|[1,0]|) = (1-r)*(1/2*(p1+p2
  ))-(1-r)*|[1,0]|+r*(1/2*(p2+q3)-|[1,0]|) by RLVECT_1:34
    .= (1-r)*(1/2*(p1+p2))-(1-r)*|[1,0]|+(r*(1/2*(p2+q3))-r*|[1,0]|) by
RLVECT_1:34
    .= r*(1/2*(p2+q3))+((1-r)*(1/2*(p1+p2))-(1-r)*|[1,0]|)-r*|[1,0]| by
RLVECT_1:def 3
    .= r*(1/2*(p2+q3))+(1-r)*(1/2*(p1+p2))-(1-r)*|[1,0]|-r*|[1,0]| by
RLVECT_1:def 3
    .= r*(1/2*(p2+q3))+(1-r)*(1/2*(p1+p2))-((1-r)*|[1,0]|+r*|[1,0]|) by
RLVECT_1:27
    .= r*(1/2*(p2+q3))+(1-r)*(1/2*(p1+p2))-((1-r)+r)*|[1,0]| by RLVECT_1:def 6
    .= p2-|[1,0]| by A16,RLVECT_1:def 8;
  r < 1 by A14,A9,XREAL_1:189;
  then p2-|[1,0]| in LSeg(1/2*(p1+p2)-|[1,0]|,1/2*(p2+q3)-|[1,0]|) by A14,A9
,A17;
  then
A18: LSeg(1/2*(p1+p2)-|[1,0]|,1/2*(p2+q3)-|[1,0]|) = LSeg(1/2*(p1+p2)-|[1,0
  ]|,p2-|[1,0]|) \/ LSeg(p2-|[1,0]|,1/2*(p2+q3)-|[1,0]|) by TOPREAL1:5;
  LSeg(1/2*(p1+p2)-|[1,0]|,p2-|[1,0]|) c= I1 \/ { p2-|[1,0]| } by A2,A12,Th49;
  hence thesis by A18,A8,A7,XBOOLE_1:13;
end;
