reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);
reserve D for non empty set,
  bD for FinSequence of D,
  b,f,g for FinSequence of K,
  MD for Matrix of D;

theorem Th70:
  for W be Subspace of m-VectSp_over K ex A be Matrix of dim W,m,K
, N be without_zero finite Subset of NAT st N c= Seg m & dim W = card N & Segm(
  A,Seg dim W,N)=1.(K,dim W) & the_rank_of A = dim W & lines A is Basis of W
proof
  let W be Subspace of m-VectSp_over K;
  consider I be finite Subset of W such that
A1: I is Basis of W by MATRLIN:def 1;
  I is linearly-independent by A1,VECTSP_7:def 3;
  then reconsider U=I as linearly-independent Subset of m-VectSp_over K by
VECTSP_9:11;
  defpred P[set,set] means for A be Matrix of card I,m,K,B be Matrix of card I
,m,K st $1=A holds A is without_repeated_line & lines A is linearly-independent
  & Lin(lines A)=(Omega).W;
  deffunc F(Matrix of card I,m,K,Nat,Nat,Element of K) = $1;
  consider M be Matrix of card I,m,K such that
A2: M is without_repeated_line & lines M = U by MATRIX13:104;
A3: for A9 be Matrix of card I,m,K, B9 be Matrix of card I,m,K st P[A9,B9]
  for a be Element of K for i,j st j in dom A9 & (i=j implies a<>-1_K) holds P[
  RLine(A9,i,Line(A9,i) + a*Line(A9,j)),F(B9,i,j,a)]
  proof
    let A9 be Matrix of card I,m,K, B9 be Matrix of card I,m,K such that
A4: P[A9,B9];
A5: dom A9=Seg len A9 by FINSEQ_1:def 3;
    let a be Element of K;
    let i,j such that
A6: j in dom A9 &( i = j implies a <> -1_K);
    set R=RLine(A9,i,Line(A9,i) + a*Line(A9,j));
A7: A9 is without_repeated_line by A4;
    then
A8: Lin lines A9= Lin lines R by A6,Th69;
    lines A9 is linearly-independent by A4;
    then card I = the_rank_of A9 by A7,MATRIX13:121
      .= the_rank_of R by A6,A5,MATRIX13:92;
    hence thesis by A4,A8,MATRIX13:121;
  end;
  Lin(I) = the ModuleStr of W by A1,VECTSP_7:def 3;
  then
A9: P[M,M] by A2,VECTSP_9:17;
  consider A9 be Matrix of card I,m,K, B9 be Matrix of card I,m,K,N such that
A10: N c= Seg m and
A11: the_rank_of M = the_rank_of A9 & the_rank_of M = card N & P[A9,B9] and
A12: Segm(A9,Seg card N,N) = 1.(K,card N) and
  for i st i in dom A9 & i > card N holds Line(A9,i) = m|->0.K and
  for i,j st i in Seg card N & j in Seg width A9 & j < Sgm N.i holds A9*(i
  ,j) = 0.K from GAUSS2(A9,A3);
  dim W = card I by A1,VECTSP_9:def 1;
  then reconsider A9 as Matrix of dim W,m,K;
  lines A9 c= the carrier of Lin(lines A9)
  by VECTSP_7:8,STRUCT_0:def 5;
  then reconsider lA=lines A9 as linearly-independent Subset of W by A11,
VECTSP_9:12;
  take A9,N;
A13: Lin(lA) = Lin(lines A9) by VECTSP_9:17;
A14: the_rank_of M = card I by A2,MATRIX13:121;
A15: card I=dim W by A1,VECTSP_9:def 1;
  Lin(lines A9) = the ModuleStr of W by A11;
  hence thesis by A15,A10,A11,A12,A14,A13,VECTSP_7:def 3;
end;
