reserve i,j,k,n,m for Nat,
        X for set,
        b,s for bag of X,
        x for object;
reserve O for Ordinal,
        R for right_zeroed add-associative right_complementable
          right_unital distributive non trivial doubleLoopStr,
        p for Polynomial of O, R;
reserve O for Ordinal,
        R for right_zeroed add-associative right_complementable
             right_unital distributive non trivial doubleLoopStr,
        p for Polynomial of O, R;

theorem Th70:
  for m be non trivial Nat, M be Jpolynom of m,F_Complex
    for f be Function of m,F_Real
  holds
    eval(Jsqrt M,f)=0 iff ex A be Subset of Seg m\{1} st
      (the addF of F_Complex) "**"
      SignGen(_sqrt XFS2FS(@f),the addF of F_Complex,A) = 0
proof
  let m be non trivial Nat;
  let M be Jpolynom of m,F_Complex;
  let f be Function of m,F_Real;
  reconsider F = XFS2FS(@f) as FinSequence of REAL;
  set MC = the multF of F_Complex,AC=the addF of F_Complex;
  rng (FS2XFS F) c= COMPLEX by NUMBERS:11;
  then
A1: rng (FS2XFS F) c= the carrier of F_Complex by COMPLFLD:def 1;
A2: len F = len (FS2XFS F) = len @f = m by AFINSQ_1:def 8,CARD_1:def 7;
  then reconsider xf = FS2XFS F as Function of m,F_Complex by A1,FUNCT_2:2;
A3:len _sqrt(F) =m by A2,Def11;
  then reconsider cF = _sqrt(F) as m-element FinSequence of F_Complex
  by CARD_1:def 7;
A4: rng (FS2XFS cF) c= the carrier of F_Complex by RELAT_1:def 19;
  dom (FS2XFS cF) = m by A3,AFINSQ_1:def 8;
  then reconsider fcf = FS2XFS cF as Function of m,F_Complex
  by A4,FUNCT_2:2;
A5:m>1 by NEWTON03:def 1;
A6: Jsqrt M = JsqrtSeries M by NEWTON03:def 1,Def13;
  eval(Jsqrt M,f) = eval(JsqrtSeries M,xf) by A6,Th69;
  then eval(Jsqrt M,f) = eval(M,fcf) by Th66;
  then
A7: eval(Jsqrt M,f) = SignGenOp(cF,MC,AC,Seg m\{1}) by A5,Def10;
  set B= Seg m\{1}, theE= the Enumeration of bool B;
  set CE= SignGenOp(cF,AC,bool B) * theE;
A8: SignGenOp(cF,MC,AC,B) = MC $$ ([#]dom CE,AC "**" CE ) by HILB10_7:def 13;
  defpred P[set] means for X be Element of Fin dom CE st X=$1 holds
  MC $$ ( X,AC "**" CE) = 0.F_Complex iff ex x st x in X & 0.F_Complex
  = (AC "**" CE).x;
A9: MC = multcomplex by COMPLFLD:def 1;
  MC $$ ( {}.dom CE,AC "**" CE) = the_unity_wrt MC by SETWISEO:31
  .= 1 by BINOP_2:6,COMPLFLD:def 1,A9;
  then
A10:P[{}.dom CE] by COMPLFLD:def 1;
A11: for B9 being (Element of Fin dom CE), b being Element of dom CE holds
  P[B9] & not b in B9 implies P[B9 \/ {b}]
  proof
    let B9 being (Element of Fin dom CE), b being Element of dom CE such that
A12: P[B9]& not b in B9;
    let X be Element of Fin dom CE such that
A13:  X=B9 \/ {b};
A14: MC $$ ( X,AC "**" CE) = (MC $$ (B9,AC "**" CE)) * ((AC "**" CE).b)
    by A12,A13,SETWOP_2:2;
    thus   MC $$ ( X,AC "**" CE) = 0.F_Complex  implies ex x st x in X &
    0.F_Complex = (AC "**" CE).x
    proof
      assume MC $$ ( X,AC "**" CE) = 0.F_Complex;
      then per cases by A14,VECTSP_1:12;
      suppose (MC $$ (B9,AC "**" CE))= 0.F_Complex;
        then consider x such that
A15:    x in B9 & 0.F_Complex = (AC "**" CE).x by A12;
        x in X by A15,A13,ZFMISC_1:136;
        hence thesis by A15;
      end;
      suppose
A16:    (AC "**" CE).b = 0.F_Complex;
        take b;
        thus thesis by A16,A13,ZFMISC_1:136;
      end;
    end;
    given x such that
A17: x in X & 0.F_Complex = (AC "**" CE).x;
    per cases by A17,A13,ZFMISC_1:136;
    suppose x=b;
      hence MC $$ ( X,AC "**" CE) = 0.F_Complex by A17, A14;
    end;
    suppose x in B9;
      then MC $$ ( B9,AC "**" CE) = 0.F_Complex by A17,A12;
      hence  MC $$ ( X,AC "**" CE) = 0.F_Complex by A14;
    end;
  end;
A18: for B being Element of Fin dom CE holds P[B] from SETWISEO:sch 2(A10,A11);
  then
A19: MC $$ ([#]dom CE,AC "**" CE) = 0.F_Complex  iff
  ex x st x in [#]dom CE & 0.F_Complex = (AC "**" CE).x;
A20: len CE = len theE by CARD_1:def 7;
  then
A21: dom CE = dom theE by FINSEQ_3:29;
  thus eval(Jsqrt M,f) = 0 implies
    ex A be Subset of Seg m\{1} st AC "**" SignGen(_sqrt XFS2FS(@f),AC,A) = 0
  proof
    assume eval(Jsqrt M,f)=0;
    then MC $$ ([#]dom CE,AC "**" CE) = 0.F_Complex by A8,A7,COMPLFLD:def 1;
    then consider x such that
A22: x in [#]dom CE & 0.F_Complex = (AC "**" CE).x by A18;
A23:x in dom CE by A22,HILB10_7:def 1;
    then reconsider x as Nat;
    theE.x in rng theE = bool B by A21,A23,FUNCT_1:def 3,RLAFFIN3:def 1;
    then reconsider Ex = theE.x as Subset of B;
    take Ex;
A24: (AC "**" CE).x = AC "**" (CE.x) by A23,HILB10_7:def 10;
    x in dom CE by A22,HILB10_7:def 1;
    then CE.x = SignGen(cF,AC,Ex) by HILB10_7:80;
    hence thesis by COMPLFLD:def 1,A22,A24;
  end;
  given A be Subset of Seg m\{1} such that
A25: AC "**" SignGen(_sqrt XFS2FS(@f),AC,A) = 0;
  A in bool B = rng theE = bool B by RLAFFIN3:def 1;
  then consider x such that
A26: x in dom theE & theE.x = A by FUNCT_1:def 3;
  reconsider x as Nat by A26;
A27: x in dom CE by A26,A20,FINSEQ_3:29;
A28: x in [#]dom CE by A26,A21,HILB10_7:def 1;
A29: SignGen(cF,AC,theE.x) = CE.x by A26,HILB10_7:80;
  AC "**" SignGen(cF,AC,theE.x) = 0.F_Complex by A26,A25,COMPLFLD:def 1;
  then (AC "**" CE).x = 0.F_Complex by A29,HILB10_7:def 10,A27;
  hence eval(Jsqrt M,f)=0 by A8,A7,A28,A19,COMPLFLD:def 1;
end;
