reserve n,m,k,i for Nat,
  g,s,t,p for Real,
  x,y,z for object, X,Y,Z for set,
  A1 for SetSequence of X,
  F1 for FinSequence of bool X,
  RFin for real-valued FinSequence,
  Si for SigmaField of X,
  XSeq,YSeq for SetSequence of Si,
  Omega for non empty set,
  Sigma for SigmaField of Omega,
  ASeq,BSeq for SetSequence of Sigma,
  P for Probability of Sigma;
reserve FSeq for FinSequence of Sigma;

theorem Th70:
  for F being Field_Subset of X holds F is SigmaField of X iff F
  is MonotoneClass of X
proof
  let F be Field_Subset of X;
  thus F is SigmaField of X implies F is MonotoneClass of X
  proof
    assume F is SigmaField of X;
    then reconsider F as SigmaField of X;
A1: for A1 being SetSequence of X st A1 is non-descending & rng A1 c= F
    holds Union A1 in F
    proof
      let A1 be SetSequence of X;
      assume that
      A1 is non-descending and
A2:   rng A1 c= F;
      reconsider A2=A1 as SetSequence of F by A2,RELAT_1:def 19;
      Union A2 in F by PROB_1:17;
      hence thesis;
    end;
    F is non-increasing-closed
    by PROB_1:def 6;
    hence thesis by A1,Def7;
  end;
  assume
A3: F is MonotoneClass of X;
  for A1 being SetSequence of X st rng A1 c= F holds Intersection A1 in F
  proof
    let A1 such that
A4: rng A1 c= F;
    set A2 = Partial_Intersection A1;
    defpred P[Nat] means A2.$1 in F;
A5: for k st P[k] holds P[k+1]
    proof
      let k;
      assume
A6:   A2.k in F;
      A1.(k+1) in rng A1 & A2.(k+1) = A2.k /\ A1.(k+1) by Def1,NAT_1:51;
      hence A2.(k+1) in F by A4,A6,FINSUB_1:def 2;
    end;
    A1.0 in rng A1 & A2.0 = A1.0 by Def1,NAT_1:51;
    then
A7: P[0] by A4;
    for k holds P[k] from NAT_1:sch 2(A7,A5);
    then
A8: rng A2 c= F by NAT_1:52;
    A2 is non-ascending by Th10;
    then Intersection A2 in F by A3,A8,Def8;
    hence thesis by Th14;
  end;
  hence thesis by PROB_1:def 6;
end;
