reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th71:
  for p,q being Point of TOP-REAL 2,
  f being Function of TOP-REAL 2,TOP-REAL 2 st
  f=Sq_Circ & p in LSeg(|[-1,-1]|,|[-1,1]|) & q in LSeg(|[-1,-1]|,|[-1,1]|)
  & p`2>=q`2 & p`2<0 holds (f.p)`2>=(f.q)`2
proof
  let p,q be Point of TOP-REAL 2, f be Function of TOP-REAL 2,TOP-REAL 2;
  assume that
A1: f=Sq_Circ and
A2: p in LSeg(|[-1,-1]|,|[-1,1]|) and
A3: q in LSeg(|[-1,-1]|,|[-1,1]|) and
A4: p`2>=q`2 and
A5: p`2<0;
A6: p`1=-1 by A2,Th1;
A7: -1<=p`2 by A2,Th1;
  (p`2)^2 >=0 by XREAL_1:63;
  then
A8: sqrt(1+(p`2)^2)>0 by SQUARE_1:25;
  (q`2)^2 >=0 by XREAL_1:63;
  then
A9: sqrt(1+(q`2)^2)>0 by SQUARE_1:25;
A10: p`2<=-p`1 by A5,A6;
  p<>0.TOP-REAL 2 by A5,EUCLID:52,54;
  then f.p= |[p`1/sqrt(1+(p`2/p`1)^2),p`2/sqrt(1+(p`2/p`1)^2)]|
  by A1,A6,A7,A10,JGRAPH_3:def 1;
  then
A11: (f.p)`2= p`2/sqrt(1+(p`2/(-1))^2) by A6,EUCLID:52
    .=(p`2)/sqrt(1+(p`2)^2);
A12: q`1=-1 by A3,Th1;
A13: -1<=q`2 by A3,Th1;
A14: q`2<=-q`1 by A4,A5,A12;
  q<>0.TOP-REAL 2 by A4,A5,EUCLID:52,54;
  then f.q= |[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|
  by A1,A12,A13,A14,JGRAPH_3:def 1;
  then
A15: (f.q)`2= q`2/sqrt(1+(q`2/(-1))^2) by A12,EUCLID:52
    .=(q`2)/sqrt(1+(q`2)^2);
  (p`2)*sqrt(1+(q`2)^2)>= (q`2)*sqrt(1+(p`2)^2) by A4,A5,Lm2;
  then (p`2)*sqrt(1+(q`2)^2)/sqrt(1+(q`2)^2)
  >= (q`2)*sqrt(1+(p`2)^2)/sqrt(1+(q`2)^2) by A9,XREAL_1:72;
  then (p`2) >= (q`2)*sqrt(1+(p`2)^2)/sqrt(1+(q`2)^2) by A9,XCMPLX_1:89;
  then (p`2)/sqrt(1+(p`2)^2)
  >= (q`2)*sqrt(1+(p`2)^2)/sqrt(1+(q`2)^2)/sqrt(1+(p`2)^2) by A8,XREAL_1:72;
  then (p`2)/sqrt(1+(p`2)^2)
  >= (q`2)*sqrt(1+(p`2)^2)/sqrt(1+(p`2)^2)/sqrt(1+(q`2)^2) by XCMPLX_1:48;
  hence thesis by A8,A11,A15,XCMPLX_1:89;
end;
