reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th71:
  for f be PartFunc of CNS1,CNS2 st f is_continuous_on X holds ||.
  f.|| is_continuous_on X & -f is_continuous_on X
proof
  let f be PartFunc of CNS1,CNS2;
  assume
A1: f is_continuous_on X;
  thus ||.f.|| is_continuous_on X
  proof
A2: X c= dom f by A1;
    hence
A3: X c= dom (||.f.|| ) by NORMSP_0:def 3;
    let r be Point of CNS1;
    assume
A4: r in X;
    then
A5: f|X is_continuous_in r by A1;
    thus (||.f.|| )|X is_continuous_in r
    proof
A6:   r in dom (||.f.|| ) /\ X by A3,A4,XBOOLE_0:def 4;
      hence r in dom ((||.f.|| )|X) by RELAT_1:61;
      let s1 be sequence of CNS1;
      assume that
A7:   rng s1 c= dom ((||.f.|| )|X) and
A8:   s1 is convergent & lim s1 = r;
      rng s1 c= dom (||.f.|| ) /\ X by A7,RELAT_1:61;
      then rng s1 c= dom f /\ X by NORMSP_0:def 3;
      then
A9:   rng s1 c= dom (f|X) by RELAT_1:61;
      then
A10:  (f|X)/.r = lim ((f|X)/*s1) by A5,A8;
      now
        let n;
        dom s1 = NAT by FUNCT_2:def 1;
        then
A11:    s1.n in rng s1 by FUNCT_1:3;
        then s1.n in dom (f|X) by A9;
        then
A12:    s1.n in dom f /\ X by RELAT_1:61;
        then
A13:    s1.n in X by XBOOLE_0:def 4;
        s1.n in dom f by A12,XBOOLE_0:def 4;
        then
A14:    s1.n in dom (||.f.|| ) by NORMSP_0:def 3;
        thus (||.(f|X)/*s1.||).n = ||. ((f|X)/*s1).n .|| by NORMSP_0:def 4
          .=||.(f|X)/.(s1.n).|| by A9,FUNCT_2:109
          .=||.f/.(s1.n).|| by A9,A11,PARTFUN2:15
          .=(||.f.|| ).(s1.n) by A14,NORMSP_0:def 3
          .=((||.f.|| )|X).(s1.n) by A13,FUNCT_1:49
          .=((||.f.|| )|X)/.(s1.n) by A7,A11,PARTFUN1:def 6
          .=(((||.f.|| )|X)/*s1).n by A7,FUNCT_2:109;
      end;
      then
A15:  ||.(f|X)/*s1.|| = ((||.f.|| )|X)/*s1 by FUNCT_2:63;
A16:  (f|X)/*s1 is convergent by A5,A8,A9;
      hence ((||.f.|| )|X)/*s1 is convergent by A15,CLVECT_1:117;
      ||.(f|X)/.r.|| = ||.f/.r.|| by A2,A4,PARTFUN2:17
        .= (||.f.|| ).r by A3,A4,NORMSP_0:def 3
        .= (||.f.|| )/.r by A3,A4,PARTFUN1:def 6
        .= ((||.f.|| )|X)/.r by A6,PARTFUN2:16;
      hence thesis by A16,A10,A15,CLOPBAN1:19;
    end;
  end;
  (-1r)(#)f is_continuous_on X by A1,Th68;
  hence thesis by VFUNCT_2:23;
end;
