reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th72:
  for S being 1-1-connectives (4,1) integer (11,1,1)-array 11 array-correct
  bool-correct non empty non void BoolSignature
  for I being integer SortSymbol of S
  for A being (4,1) integer (11,1,1)-array bool-correct non-empty
  MSAlgebra over S
  for a,b being Element of A,I st a = 0
  holds init.array(a,b) = {}
  proof
    let S be 1-1-connectives (4,1) integer (11,1,1)-array 11 array-correct
    bool-correct non empty non void BoolSignature;
    let I be integer SortSymbol of S;
    let A be (4,1) integer (11,1,1)-array bool-correct non-empty
    MSAlgebra over S;
    let a,b be Element of A,I;
    assume A1: a = 0;
    set o = (the connectives of S).14;
    consider J,K being Element of S such that
A2: K = 1 & (the connectives of S).11 is_of_type <*J,1*>, K &
    (the Sorts of A).J = ((the Sorts of A).K)^omega &
    (the Sorts of A).1 = INT &
    (for a being 0-based finite array of (the Sorts of A).K holds
    (for i being Integer st i in dom a holds
    Den((the connectives of S)/.11,A).<*a,i*> = a.i &
    for x being Element of A,K holds
    Den((the connectives of S)/.(11+1),A).<*a,i,x*> = a+*(i,x)) &
    Den((the connectives of S)/.(11+2),A).<*a*> = card a) &
    for i being Integer, x being Element of A,K st i >= 0 holds
    Den((the connectives of S)/.(11+3),A).<*i,x*> = Segm(i)-->x
      by AOFA_A00:def 52;
A3: I = 1 by AOFA_A00:def 40;
    11+3 <= len the connectives of S by AOFA_A00:def 51;
    then 14 in dom the connectives of S by FINSEQ_3:25;
    then o = (the connectives of S)/.14 & o in the carrier' of S
    by FUNCT_1:102,PARTFUN1:def 6;
    hence init.array(a,b) = Den((the connectives of S)/.14, A).<*a,b*>
    by SUBSET_1:def 8
    .= Segm(0 qua set)-->b by A1,A2,A3
    .= {};
  end;
