reserve x,y for set;
reserve C,C9,D,D9,E for non empty set;
reserve c for Element of C;
reserve c9 for Element of C9;
reserve d,d1,d2,d3,d4,e for Element of D;
reserve d9 for Element of D9;
reserve i,j for natural Number;
reserve F for Function of [:D,D9:],E;
reserve p,q for FinSequence of D,
  p9,q9 for FinSequence of D9;
reserve f,f9 for Function of C,D,
  h for Function of D,E;
reserve T,T1,T2,T3 for Tuple of i,D;
reserve T9 for Tuple of i, D9;
reserve S for Tuple of j, D;
reserve S9 for Tuple of j, D9;
reserve F,G for BinOp of D;
reserve u for UnOp of D;
reserve H for BinOp of E;

theorem Th72:
  F is associative & F is having_an_inverseOp & F is having_a_unity &
  F.:(f,f9) = C-->the_unity_wrt F implies
  f = (the_inverseOp_wrt F)*f9 & (the_inverseOp_wrt F)*f = f9
proof
  assume that
A1: F is associative & F is having_an_inverseOp & F is having_a_unity and
A2: F.:(f,f9) = C-->the_unity_wrt F;
  set u = the_inverseOp_wrt F;
  set e = the_unity_wrt F;
  reconsider g = C-->e as Function of C,D;
  now
    let c;
    F.(f.c,f9.c) = g.c by A2,FUNCOP_1:37
      .= e;
    hence f.c = u.(f9.c) by A1,Th60
      .= (u*f9).c by FUNCT_2:15;
  end;
  hence f = (the_inverseOp_wrt F)*f9 by FUNCT_2:63;
  now
    let c;
    F.(f.c,f9.c) = g.c by A2,FUNCOP_1:37
      .= e;
    then f9.c = u.(f.c) by A1,Th60;
    hence (u*f).c = f9.c by FUNCT_2:15;
  end;
  hence thesis by FUNCT_2:63;
end;
