reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem
  1 < width G & 1 <= i & i+1 < len G implies LSeg(1/2*(G*(i,1)+G*(i+1,1)
)-|[0,1]|,1/2*(G*(i+1,1)+G*(i+2,1))-|[0,1]|) c= Int cell(G,i,0) \/ Int cell(G,i
  +1,0) \/ { G*(i+1,1)-|[0,1]| }
proof
  assume that
A1: 1 < width G and
A2: 1 <= i and
A3: i+1 < len G;
  set p1 = G*(i,1), p2 = G*(i+1,1), q3 = G*(i+2,1), r = (p2`1-p1`1)/(q3`1-p1`1
  );
A4: i+1+1 = i+(1+1);
  then
A5: i+2 >= 1 by NAT_1:11;
A6: i+(1+1) <= len G by A3,A4,NAT_1:13;
  set I1 = Int cell(G,i,0), I2 = Int cell(G,i+1,0);
A7: I1 \/ I2 \/ { p2-|[0,1]| } = I1 \/ (I2 \/ ({ p2-|[0,1]| } \/ { p2-|[0,1
  ]| })) by XBOOLE_1:4
    .= I1 \/ (I2 \/ { p2-|[0,1]| } \/ { p2-|[0,1]| }) by XBOOLE_1:4
    .= I1 \/ { p2-|[0,1]| } \/ (I2 \/ { p2-|[0,1]| }) by XBOOLE_1:4;
A8: LSeg(1/2*(p2+q3)-|[0,1]|,p2-|[0,1]|) c= I2 \/ { p2-|[0,1]| } by A3,A4,Th52,
NAT_1:11;
  i < i+1 by XREAL_1:29;
  then p1`1 < p2`1 by A1,A2,A3,GOBOARD5:3;
  then
A9: p2`1-p1`1 > 0 by XREAL_1:50;
A10: i+1 >= 1 by NAT_1:11;
  then
A11: p2`2 = G*(1,1)`2 by A1,A3,GOBOARD5:1
    .= q3`2 by A1,A6,A5,GOBOARD5:1;
  i <= i+1 by NAT_1:11;
  then
A12: i < len G by A3,XXREAL_0:2;
  then p1`2 = G*(1,1)`2 by A1,A2,GOBOARD5:1
    .= p2`2 by A1,A3,A10,GOBOARD5:1;
  then
A13: 1*p2`2 = (1-r)*p1`2+r*q3`2 by A11
    .= ((1-r)*p1)`2+r*q3`2 by Lm3
    .= ((1-r)*p1)`2+(r*q3)`2 by Lm3
    .= ((1-r)*p1+r*q3)`2 by Lm1;
  i+1 < i+2 by XREAL_1:6;
  then p2`1 < q3`1 by A1,A10,A6,GOBOARD5:3;
  then
A14: p2`1-p1`1 < q3`1-p1`1 by XREAL_1:9;
  then r*(q3`1-p1`1) = p2`1-p1`1 by A9,XCMPLX_1:87;
  then p2`1 = (1-r)*p1`1 +r*q3`1;
  then 1*p2`1 = ((1-r)*p1)`1+r*q3`1 by Lm3
    .= ((1-r)*p1)`1+(r*q3)`1 by Lm3
    .= ((1-r)*p1+(r*q3))`1 by Lm1;
  then
A15: (1-r)*p1+r*q3 = |[p2`1,p2`2]| by A13,EUCLID:53
    .= p2 by EUCLID:53;
  p2 = 1*p2 by RLVECT_1:def 8
    .= 1/2*p2+1/2*p2 by Lm7,RLVECT_1:def 6
    .= 1/2*(((1-r)+r)*p2) + 1/2*((1-r)*p1+r*q3) by A15,RLVECT_1:def 8
    .= 1/2*((1-r)*p2+r*p2) + 1/2*((1-r)*p1+r*q3) by RLVECT_1:def 6
    .= 1/2*((1-r)*p2)+1/2*(r*p2) + 1/2*((1-r)*p1+r*q3) by RLVECT_1:def 5
    .= 1/2*((1-r)*p2)+1/2*(r*p2) + (1/2*((1-r)*p1)+1/2*(r*q3)) by
RLVECT_1:def 5
    .= 1/2*((1-r)*p2)+(1/2*(r*p2) + (1/2*((1-r)*p1)+1/2*(r*q3))) by
RLVECT_1:def 3
    .= 1/2*((1-r)*p2)+(1/2*((1-r)*p1)+(1/2*(r*p2)+1/2*(r*q3))) by
RLVECT_1:def 3
    .= 1/2*((1-r)*p2)+1/2*((1-r)*p1)+(1/2*(r*p2)+1/2*(r*q3)) by RLVECT_1:def 3
    .= (1/2*((1-r)*p2)+1/2*((1-r)*p1))+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 3
    .= 1/2*((1-r)*p2+(1-r)*p1)+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 5
    .= 1/2*((1-r)*(p1+p2))+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 5
    .= 1/2*(1-r)*(p1+p2)+1/2*(r*p2)+1/2*(r*q3) by RLVECT_1:def 7
    .= 1/2*(1-r)*(p1+p2)+(1/2*(r*p2)+1/2*(r*q3)) by RLVECT_1:def 3
    .= 1/2*(1-r)*(p1+p2)+1/2*(r*p2+r*q3) by RLVECT_1:def 5;
  then
A16: p2 = 1/2*(1-r)*(p1+p2)+1/2*(r*(p2+q3)) by RLVECT_1:def 5
    .= (1-r)*(1/2*(p1+p2))+1/2*(r*(p2+q3)) by RLVECT_1:def 7
    .= (1-r)*(1/2*(p1+p2))+1/2*r*(p2+q3) by RLVECT_1:def 7
    .= (1-r)*((1/2)*(p1+p2))+r*((1/2)*(p2+q3)) by RLVECT_1:def 7;
A17: (1-r)*(1/2*(p1+p2)-|[0,1]|)+r*(1/2*(p2+q3)-|[0,1]|) = (1-r)*(1/2*(p1+p2
  ))-(1-r)*|[0,1]|+r*(1/2*(p2+q3)-|[0,1]|) by RLVECT_1:34
    .= (1-r)*(1/2*(p1+p2))-(1-r)*|[0,1]|+(r*(1/2*(p2+q3))-r*|[0,1]|) by
RLVECT_1:34
    .= r*(1/2*(p2+q3))+((1-r)*(1/2*(p1+p2))-(1-r)*|[0,1]|)-r*|[0,1]| by
RLVECT_1:def 3
    .= r*(1/2*(p2+q3))+(1-r)*(1/2*(p1+p2))-(1-r)*|[0,1]|-r*|[0,1]| by
RLVECT_1:def 3
    .= r*(1/2*(p2+q3))+(1-r)*(1/2*(p1+p2))-((1-r)*|[0,1]|+r*|[0,1]|) by
RLVECT_1:27
    .= r*(1/2*(p2+q3))+(1-r)*(1/2*(p1+p2))-((1-r)+r)*|[0,1]| by RLVECT_1:def 6
    .= p2-|[0,1]| by A16,RLVECT_1:def 8;
  r < 1 by A14,A9,XREAL_1:189;
  then p2-|[0,1]| in LSeg(1/2*(p1+p2)-|[0,1]|,1/2*(p2+q3)-|[0,1]|) by A14,A9
,A17;
  then
A18: LSeg(1/2*(p1+p2)-|[0,1]|,1/2*(p2+q3)-|[0,1]|) = LSeg(1/2*(p1+p2)-|[0,1
  ]|,p2-|[0,1]|) \/ LSeg(p2-|[0,1]|,1/2*(p2+q3)-|[0,1]|) by TOPREAL1:5;
  LSeg(1/2*(p1+p2)-|[0,1]|,p2-|[0,1]|) c= I1 \/ { p2-|[0,1]| } by A2,A12,Th53;
  hence thesis by A18,A8,A7,XBOOLE_1:13;
end;
