reserve G for Group;
reserve A,B for non empty Subset of G;
reserve N,H,H1,H2 for Subgroup of G;
reserve x,a,b for Element of G;
reserve N1,N2 for Subgroup of G;

theorem Th72:
  for H being Subgroup of G, N being normal Subgroup of G st N is Subgroup of H
  ex M being strict Subgroup of G st the carrier of M = N ` H
proof
   let H be Subgroup of G, N be normal Subgroup of G;
   assume
A1: N is Subgroup of H;
A2: 1_G in N ` H
   proof
     1_G in N by GROUP_2:46; then
A3:  1_G * N = carr(N) by GROUP_2:113;
     carr(N) c= carr(H) by A1,GROUP_2:def 5;
     hence thesis by A3;
   end;
A4:for x,y being Element of G holds x in N ` H & y in N ` H
   implies x * y in N ` H
   proof
     let x,y be Element of G;
     assume x in N ` H & y in N ` H;
     then x * N c= carr(H) & y * N c= carr(H) by Th49; then
A5:  (x * N) * (y * N) c= carr(H) * carr(H) by GROUP_3:4;
A6:  (x * N) * (y * N) = (x * y) * N by Th1;
     carr(H) * carr(H) = carr(H) by GROUP_2:76;
     hence thesis by A5,A6;
   end;
for x being Element of G holds x in N ` H implies x" in N ` H
   proof
     let x be Element of G;
     assume x in N ` H; then
A7:  x * N c= carr(H) by Th49;
     x in x * N by GROUP_2:108;
     then x in H by A7,STRUCT_0:def 5; then
  x" in H by GROUP_2:51;
then A8: x" * H = carr(H) by GROUP_2:113;
     x" * N c= x" * H by A1,GROUP_3:6;
     hence thesis by A8;
   end;
  hence thesis by A2,A4,GROUP_2:52;
end;
