reserve X for set, x,y,z for object,
  k,l,n for Nat,
  r for Real;
reserve i,i0,i1,i2,i3,i4,i5,i8,i9,j for Integer;
reserve r1,p,p1,g,g1,g2 for Real,
  Y for Subset of REAL;
reserve r, s for Real;
reserve i for Integer,
  a, b, r, s for Real;

theorem
  r <= a & a < r+1 & r <= b & b < r+1 & frac a = frac b implies a = b
proof
  assume that
A1: r <= a and
A2: a < r+1 and
A3: r <= b and
A4: b < r+1 and
A5: frac a = frac b;
A6: [\r/] <= r by Def6;
  then
A7: [\r/] <= a by A1,XXREAL_0:2;
A8: [\r/] <= b by A3,A6,XXREAL_0:2;
  per cases;
  suppose
A9: a < [\r/]+1 & b >= [\r/]+1;
    then frac a >= frac r by A1,Th66;
    hence thesis by A4,A5,A9,Th69;
  end;
  suppose
A10: a >= [\r/]+1 & b < [\r/]+1;
    then frac a < frac r by A2,Th69;
    hence thesis by A3,A5,A10,Th66;
  end;
  suppose
A11: a < [\r/]+1 & b < [\r/]+1;
    then b-1 < [\r/]+1-1 by XREAL_1:9;
    then
A12: [\b/] = [\r/] by A8,Def6;
    a-1 < [\r/]+1-1 by A11,XREAL_1:9;
    then [\a/] = [\r/] by A7,Def6;
    hence thesis by A5,A12;
  end;
  suppose
    a >= [\r/]+1 & b >= [\r/]+1;
    then [\a/] = [\r/]+1 & [\b/] = [\r/]+1 by A2,A4,Th68;
    hence thesis by A5;
  end;
end;
