reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th72:
  for cn being Real st -1<cn & cn<1 holds (cn-FanMorphN) is
  Function of TOP-REAL 2,TOP-REAL 2 & rng (cn-FanMorphN) = the carrier of
  TOP-REAL 2
proof
  let cn be Real;
  assume that
A1: -1<cn and
A2: cn<1;
  thus (cn-FanMorphN) is Function of TOP-REAL 2,TOP-REAL 2;
  for f being Function of TOP-REAL 2,TOP-REAL 2 st f=(cn-FanMorphN) holds
  rng (cn-FanMorphN)=the carrier of TOP-REAL 2
  proof
    let f be Function of TOP-REAL 2,TOP-REAL 2;
    assume
A3: f=(cn-FanMorphN);
A4: dom f=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
    the carrier of TOP-REAL 2 c= rng f
    proof
      let y be object;
      assume y in the carrier of TOP-REAL 2;
      then reconsider p2=y as Point of TOP-REAL 2;
      set q=p2;
      now
        per cases by JGRAPH_2:3;
        case
          q`2<=0;
          then y=(cn-FanMorphN).q by Th49;
          hence ex x being set st x in dom (cn-FanMorphN) & y=(cn-FanMorphN).x
          by A3,A4;
        end;
        case
A5:       q`1/|.q.|>=0 & q`2>=0 & q<>0.TOP-REAL 2;
          --(1+cn)>0 by A1,XREAL_1:148;
          then
A6:       -(-1-cn)>0;
A7:       1-cn>=0 by A2,XREAL_1:149;
          then q`1/|.q.|*(1-cn)>=0 by A5;
          then -1-cn<= q`1/|.q.|*(1-cn) by A6;
          then
A8:       -1-cn+cn<= q`1/|.q.|*(1-cn)+cn by XREAL_1:7;
          set px=|[ |.q.|*(q`1/|.q.|*(1-cn)+cn), (|.q.|)*sqrt(1-(q`1/|.q.|*(1-
          cn)+cn)^2)]|;
A9:       px`1 = |.q.|*(q`1/|.q.|*(1-cn)+cn) by EUCLID:52;
          |.q.|<>0 by A5,TOPRNS_1:24;
          then
A10:      |.q.|^2>0 by SQUARE_1:12;
A11:      dom (cn-FanMorphN)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
A12:      1-cn>0 by A2,XREAL_1:149;
          0<=(q`2)^2 by XREAL_1:63;
          then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`1)^2<=(q`1)^2+(q`2)^2 by
JGRAPH_3:1,XREAL_1:7;
          then (q`1)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
          then (q`1)^2/(|.q.|)^2 <= 1 by A10,XCMPLX_1:60;
          then ((q`1)/|.q.|)^2 <= 1 by XCMPLX_1:76;
          then q`1/|.q.|<=1 by SQUARE_1:51;
          then q`1/|.q.|*(1-cn) <=1 *(1-cn) by A12,XREAL_1:64;
          then q`1/|.q.|*(1-cn)+cn-cn <=1-cn;
          then (q`1/|.q.|*(1-cn)+cn) <=1 by XREAL_1:9;
          then 1^2>=(q`1/|.q.|*(1-cn)+cn)^2 by A8,SQUARE_1:49;
          then
A13:      1-(q`1/|.q.|*(1-cn)+cn)^2>=0 by XREAL_1:48;
          then
A14:      sqrt(1-(q`1/|.q.|*(1-cn)+cn)^2)>=0 by SQUARE_1:def 2;
A15:      px`2 = (|.q.|)*sqrt(1-(q`1/|.q.|*(1-cn)+cn)^2) by EUCLID:52;
          then
          |.px.|^2=((|.q.|)*sqrt(1-(q`1/|.q.|*(1-cn)+cn)^2))^2 +(|.q.|*(q
          `1/|.q.|*(1-cn)+cn))^2 by A9,JGRAPH_3:1
            .=(|.q.|)^2*(sqrt(1-(q`1/|.q.|*(1-cn)+cn)^2))^2 +(|.q.|)^2*((q`1
          /|.q.|*(1-cn)+cn))^2;
          then
A16:      |.px.|^2=(|.q.|)^2*(1-(q`1/|.q.|*(1-cn)+cn)^2) +(|.q.|)^2*((q`1
          /|.q.|*(1-cn)+cn))^2 by A13,SQUARE_1:def 2
            .= (|.q.|)^2;
          then
A17:      |.px.|=sqrt(|.q.|^2) by SQUARE_1:22
            .=|.q.| by SQUARE_1:22;
          then
A18:      px<>0.TOP-REAL 2 by A5,TOPRNS_1:23,24;
          (q`1/|.q.|*(1-cn)+cn)>=0+cn by A5,A7,XREAL_1:7;
          then px`1/|.px.| >=cn by A5,A9,A17,TOPRNS_1:24,XCMPLX_1:89;
          then
A19:      (cn-FanMorphN).px =|[ |.px.|* ((px`1/|.px.|-cn)/(1-cn) ), |.px
.|*( sqrt(1-((px`1/|.px.|-cn)/(1-cn))^2))]| by A1,A2,A15,A14,A18,Th51;
A20:      |.px.|*( sqrt((q`2/|.q.|)^2))=|.q.|*(q`2/|.q.|) by A5,A17,SQUARE_1:22
            .=q`2 by A5,TOPRNS_1:24,XCMPLX_1:87;
A21:      |.px.|* ((px`1/|.px.|-cn)/(1-cn)) =|.q.|* (( ((q`1/|.q.|*(1-cn)
          +cn))-cn)/(1-cn)) by A5,A9,A17,TOPRNS_1:24,XCMPLX_1:89
            .=|.q.|* ( q`1/|.q.|) by A12,XCMPLX_1:89
            .= q`1 by A5,TOPRNS_1:24,XCMPLX_1:87;
          then
          |.px.|*( sqrt(1-((px`1/|.px.|-cn)/(1-cn))^2)) = |.px.|*( sqrt(1
          -(q`1/|.px.|)^2)) by A5,A17,TOPRNS_1:24,XCMPLX_1:89
            .= |.px.|*( sqrt(1-(q`1)^2/(|.px.|)^2)) by XCMPLX_1:76
            .= |.px.|*( sqrt( (|.px.|)^2/(|.px.|)^2-(q`1)^2/(|.px.|)^2)) by A10
,A16,XCMPLX_1:60
            .= |.px.|*( sqrt( ((|.px.|)^2-(q`1)^2)/(|.px.|)^2)) by XCMPLX_1:120
            .= |.px.|*( sqrt( ((q`1)^2+(q`2)^2-(q`1)^2)/(|.px.|)^2)) by A16,
JGRAPH_3:1
            .= |.px.|*( sqrt((q`2/|.q.|)^2)) by A17,XCMPLX_1:76;
          hence ex x being set st x in dom (cn-FanMorphN) & y=(cn-FanMorphN).x
          by A19,A21,A20,A11,EUCLID:53;
        end;
        case
A22:      q`1/|.q.|<0 & q`2>=0 & q<>0.TOP-REAL 2;
A23:      1+cn>=0 by A1,XREAL_1:148;
          (1-cn)>0 by A2,XREAL_1:149;
          then
A24:      1-cn+cn>= q`1/|.q.|*(1+cn)+cn by A22,A23,XREAL_1:7;
A25:      1+cn>0 by A1,XREAL_1:148;
          |.q.|<>0 by A22,TOPRNS_1:24;
          then
A26:      |.q.|^2>0 by SQUARE_1:12;
          0<=(q`2)^2 by XREAL_1:63;
          then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`1)^2<=(q`1)^2+(q`2)^2 by
JGRAPH_3:1,XREAL_1:7;
          then (q`1)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
          then (q`1)^2/(|.q.|)^2 <= 1 by A26,XCMPLX_1:60;
          then ((q`1)/|.q.|)^2 <= 1 by XCMPLX_1:76;
          then q`1/|.q.|>=-1 by SQUARE_1:51;
          then q`1/|.q.|*(1+cn) >=(-1)*(1+cn) by A25,XREAL_1:64;
          then q`1/|.q.|*(1+cn)+cn-cn >=-1-cn;
          then (q`1/|.q.|*(1+cn)+cn) >=-1 by XREAL_1:9;
          then 1^2>=(q`1/|.q.|*(1+cn)+cn)^2 by A24,SQUARE_1:49;
          then
A27:      1-(q`1/|.q.|*(1+cn)+cn)^2>=0 by XREAL_1:48;
          then
A28:      sqrt(1-(q`1/|.q.|*(1+cn)+cn)^2)>=0 by SQUARE_1:def 2;
A29:      dom (cn-FanMorphN)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
          set px=|[ |.q.|*(q`1/|.q.|*(1+cn)+cn), (|.q.|)*sqrt(1-(q`1/|.q.|*(1+
          cn)+cn)^2)]|;
A30:      px`1 = |.q.|*(q`1/|.q.|*(1+cn)+cn) by EUCLID:52;
A31:      px`2 = (|.q.|)*sqrt(1-(q`1/|.q.|*(1+cn)+cn)^2) by EUCLID:52;
          then
          |.px.|^2=((|.q.|)*sqrt(1-(q`1/|.q.|*(1+cn)+cn)^2))^2 +(|.q.|*(q
          `1/|.q.|*(1+cn)+cn))^2 by A30,JGRAPH_3:1
            .=(|.q.|)^2*(sqrt(1-(q`1/|.q.|*(1+cn)+cn)^2))^2 +(|.q.|)^2*((q`1
          /|.q.|*(1+cn)+cn))^2;
          then
A32:      |.px.|^2=(|.q.|)^2*(1-(q`1/|.q.|*(1+cn)+cn)^2) +(|.q.|)^2*((q`1
          /|.q.|*(1+cn)+cn))^2 by A27,SQUARE_1:def 2
            .= (|.q.|)^2;
          then
A33:      |.px.|=sqrt(|.q.|^2) by SQUARE_1:22
            .=|.q.| by SQUARE_1:22;
          then
A34:      px<>0.TOP-REAL 2 by A22,TOPRNS_1:23,24;
          (q`1/|.q.|*(1+cn)+cn)<=0+cn by A22,A23,XREAL_1:7;
          then px`1/|.px.| <=cn by A22,A30,A33,TOPRNS_1:24,XCMPLX_1:89;
          then
A35:      (cn-FanMorphN).px =|[ |.px.|* ((px`1/|.px.|-cn)/(1+cn) ), |.px
.|*( sqrt(1-((px`1/|.px.|-cn)/(1+cn))^2))]| by A1,A2,A31,A28,A34,Th51;
A36:      |.px.|*( sqrt((q`2/|.q.|)^2))=|.q.|*(q`2/|.q.|) by A22,A33,
SQUARE_1:22
            .=q`2 by A22,TOPRNS_1:24,XCMPLX_1:87;
A37:      |.px.|* ((px`1/|.px.|-cn)/(1+cn)) =|.q.|* (( ((q`1/|.q.|*(1+cn)
          +cn))-cn)/(1+cn)) by A22,A30,A33,TOPRNS_1:24,XCMPLX_1:89
            .=|.q.|* ( q`1/|.q.|) by A25,XCMPLX_1:89
            .= q`1 by A22,TOPRNS_1:24,XCMPLX_1:87;
          then
          |.px.|*( sqrt(1-((px`1/|.px.|-cn)/(1+cn))^2)) = |.px.|*( sqrt(1
          -(q`1/|.px.|)^2)) by A22,A33,TOPRNS_1:24,XCMPLX_1:89
            .= |.px.|*( sqrt(1-(q`1)^2/(|.px.|)^2)) by XCMPLX_1:76
            .= |.px.|*( sqrt( (|.px.|)^2/(|.px.|)^2-(q`1)^2/(|.px.|)^2)) by A26
,A32,XCMPLX_1:60
            .= |.px.|*( sqrt( ((|.px.|)^2-(q`1)^2)/(|.px.|)^2)) by XCMPLX_1:120
            .= |.px.|*( sqrt( ((q`1)^2+(q`2)^2-(q`1)^2)/(|.px.|)^2)) by A32,
JGRAPH_3:1
            .= |.px.|*( sqrt((q`2/|.q.|)^2)) by A33,XCMPLX_1:76;
          hence ex x being set st x in dom (cn-FanMorphN) & y=(cn-FanMorphN).x
          by A35,A37,A36,A29,EUCLID:53;
        end;
      end;
      hence thesis by A3,FUNCT_1:def 3;
    end;
    hence thesis by A3,XBOOLE_0:def 10;
  end;
  hence thesis;
end;
