
theorem Th72:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`1=a & p2`1=a
& p3`1=a & p4`1=b & c <=p1`2 & p1`2<p2`2 & p2`2<p3`2 & p3`2<=d & c <=p4`2 & p4
  `2<=d & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one & g is
continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) & rng g c=
  closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`1=a and
A4: p2`1=a and
A5: p3`1=a and
A6: p4`1=b and
A7: c <=p1`2 and
A8: p1`2<p2`2 and
A9: p2`2<p3`2 and
A10: p3`2<=d and
A11: c <=p4`2 and
A12: p4`2<=d and
A13: f.0=p1 and
A14: f.1=p3 and
A15: g.0=p2 and
A16: g.1=p4 and
A17: f is continuous one-to-one and
A18: g is continuous one-to-one and
A19: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A20: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A21: p1`2<p3`2 by A8,A9,XXREAL_0:2;
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A22: -1<=((g2).I)`2 by A2,A11,A12,A16,Th60;
A23: ((g2).I)`1= 1 by A1,A6,A16,Th56;
A24: ((g2).O)`1= -1 by A1,A4,A15,Th54;
  (f.I)`1=a by A5,A14;
  then
A25: -1 <=((f2).O)`2 by A2,A7,A10,A13,A14,A21,Th58;
A26: g2 is continuous one-to-one by A1,A2,A18,Th53;
  set x = the Element of rng f2 /\ rng g2;
A27: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A28: h.p3=f2.I by A14,FUNCT_1:13;
  d-c >0 by A2,XREAL_1:50;
  then
A29: C >0 by XREAL_1:139;
  b-a>0 by A1,XREAL_1:50;
  then
A30: A >0 by XREAL_1:139;
  then
A31: (h.p1)`2<(h.p2)`2 by A8,A29,Th51;
  (f.O)`1=a by A3,A13;
  then
A32: ((f2).I)`2<=1 by A2,A7,A10,A13,A14,A21,Th58;
  h is being_homeomorphism by A30,A29,Th51;
  then
A33: h is one-to-one by TOPS_2:def 5;
A34: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A19,Th52;
A35: ((f2).I)`1= -1 by A1,A5,A14,Th54;
A36: ((f2).O)`1= -1 by A1,A3,A13,Th54;
A37: f2 is continuous one-to-one by A1,A2,A17,Th53;
A38: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
A39: (h.p2)`2<(h.p3)`2 by A9,A30,A29,Th51;
A40: ((g2).I)`2<=1 by A2,A11,A12,A16,Th60;
A41: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A42: h.p2=g2.O by A15,FUNCT_1:13;
  h.p1=f2.O by A13,A27,FUNCT_1:13;
  then rng f2 meets rng g2 by A31,A39,A42,A28,A37,A36,A35,A25,A32,A34,A26,A24
,A23,A22,A40,A38,Th16,JGRAPH_6:79;
  then
A43: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A44: z2 in dom g2 and
A45: x=g2.z2 by FUNCT_1:def 3;
A46: x=h.(g.z2) by A41,A44,A45,FUNCT_1:13;
A47: g.z2 in rng g by A41,A44,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A44,FUNCT_2:5;
  then
A48: g.z2 in dom h by FUNCT_2:def 1;
  x in rng f2 by A43,XBOOLE_0:def 4;
  then consider z1 being object such that
A49: z1 in dom f2 and
A50: x=f2.z1 by FUNCT_1:def 3;
A51: f.z1 in rng f by A27,A49,FUNCT_1:def 3;
  f.z1 in the carrier of TOP-REAL 2 by A49,FUNCT_2:5;
  then
A52: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A27,A49,A50,FUNCT_1:13;
  then f.z1=g.z2 by A46,A52,A48,A33,FUNCT_1:def 4;
  hence thesis by A51,A47,XBOOLE_0:3;
end;
