reserve i,j,k,n,m for Nat,
        X for set,
        b,s for bag of X,
        x for object;
reserve O for Ordinal,
        R for right_zeroed add-associative right_complementable
          right_unital distributive non trivial doubleLoopStr,
        p for Polynomial of O, R;
reserve O for Ordinal,
        R for right_zeroed add-associative right_complementable
             right_unital distributive non trivial doubleLoopStr,
        p for Polynomial of O, R;

theorem Th72:
  for f be FinSequence of F_Complex,A be set holds
   ex i be Integer st (i = 1 or i =-1) &
       SignGen(f,the addF of F_Complex,A).x = i * (f.x)
proof
  set AF=the addF of F_Complex;
  let f be FinSequence of F_Complex,A be set;
A1:dom SignGen(f,AF,A) = dom f by HILB10_7:def 11;
  per cases;
  suppose not x in dom f;
    then SignGen(f,AF,A).x = 0 & f.x=0 by A1,FUNCT_1:def 2;
    then SignGen(f,AF,A).x = 1* (f.x);
    hence thesis;
  end;
  suppose
A2: x in dom f;
    then
A3: f.x = f/.x by PARTFUN1:def 6;
    per cases;
    suppose x in A;
      then SignGen(f,AF,A).x = (the_inverseOp_wrt AF).(f.x)
      by A1,A2,HILB10_7:def 11
      .= (comp F_Complex).(f.x) by FVSUM_1:15
      .= -(f/.x) by A3,VECTSP_1:def 13
      .= -f.x by A2,PARTFUN1:def 6,COMPLFLD:2
      .= (-1)*(f.x);
      hence thesis;
    end;
    suppose not x in A;
      then SignGen(f,AF,A).x
      = 1*(f.x) by A1,A2,HILB10_7:def 11;
      hence thesis;
    end;
  end;
end;
