reserve p,q for Rational;
reserve g,m,m1,m2,n,n1,n2 for Nat;
reserve i,i1,i2,j,j1,j2 for Integer;
reserve R for Ring, F for Field;

theorem Th71:
for R,S being Ring holds S is R-monomorphic Ring iff S includes R
proof
let R,S be Ring;
A1: now assume S is R-monomorphic; then
   reconsider T = S as R-monomorphic Ring;
   set f = the Monomorphism of R,T;
   ker f = {0.R} by RING_2:12;
   then A2: R/(ker f), R are_isomorphic by RING_2:17;
   R/(ker f), (Image f) are_isomorphic by RING_2:15;
   hence S includes R by Th43,A2;
   end;
now assume S includes R;
   then consider T being Subring of S such that A3: T,R are_isomorphic;
   consider f being Function of R,T such that A4: f is isomorphism
     by A3,QUOFIELD:def 23;
   A5: f is additive multiplicative unity-preserving one-to-one by A4;
   the carrier of T c= the carrier of S by C0SP1:def 3; then
   reconsider g = f as Function of R,S by FUNCT_2:7;
   now let x,y be Element of R;
     A6: [f.x,f.y] in [:the carrier of T, the carrier of T:];
     thus g.(x+y) = f.x + f.y by A5
                 .= ((the addF of S)||the carrier of T).(f.x,f.y)
                    by C0SP1:def 3
                 .= g.x + g.y by A6,FUNCT_1:49;
     end;
   then A7: g is additive;
   now let x,y be Element of R;
     A8: [f.x,f.y] in [:the carrier of T, the carrier of T:];
     thus g.(x*y) = f.x * f.y by A5
                 .= ((the multF of S)||the carrier of T).(f.x,f.y)
                    by C0SP1:def 3
                 .= g.x * g.y by A8,FUNCT_1:49;
     end;
   then A9: g is multiplicative;
   g is unity-preserving by A5,C0SP1:def 3;
   hence S is R-monomorphic by A7,A9,A4;
   end;
hence thesis by A1;
end;
