reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;
reserve z for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th72:
  z/.1 = N-min L~z & E-min L~z <> S-max L~z implies (E-min L~z)..z
  < (S-max L~z)..z
proof
  set i1 = (E-min L~z)..z, i2 = (S-max L~z)..z;
  assume that
A1: z/.1 = N-min L~z and
A2: E-min L~z <> S-max L~z & i1 >= i2;
A3: S-bound L~z < N-bound L~z by TOPREAL5:16;
  z/.2 in N-most L~z by A1,Th30;
  then
A4: (z/.2)`2 = (N-min L~z)`2 by PSCOMP_1:39
    .= N-bound L~z by EUCLID:52;
A5: S-max L~z in rng z by Th42;
  then
A6: i2 in dom z by FINSEQ_4:20;
  then
A7: i2 <= len z by FINSEQ_3:25;
A8: z/.i2 = z.i2 by A6,PARTFUN1:def 6
    .= S-max L~z by A5,FINSEQ_4:19;
  then
A9: (z/.i2)`2 = S-bound L~z by EUCLID:52;
A10: 1 <= i2 by A6,FINSEQ_3:25;
A11: i2 <> 0 by A6,FINSEQ_3:25;
  (z/.1)`2 = N-bound L~z by A1,EUCLID:52;
  then i2 <> 0 & ... & i2 <> 2 by A4,A11,A9,A3;
  then
A12: i2 > 2;
  then reconsider h = mid(z,i2,2) as S-Sequence_in_R2 by A7,Th37;
A13: 2 <= len z by NAT_D:60;
  then
A14: 2 in dom z by FINSEQ_3:25;
  then h/.1 = S-max L~z by A6,A8,Th8;
  then
A15: (h/.1)`2 = S-bound L~z by EUCLID:52;
  h is_in_the_area_of z & h/.len h = z/.2 by A6,A14,Th9,Th21,Th22;
  then
A16: len h >= 2 & h is_a_v.c._for z by A4,A15,TOPREAL1:def 8;
  N-max L~z in L~z by SPRECT_1:11;
  then (N-max L~z)`1 <= E-bound L~z by PSCOMP_1:24;
  then (N-min L~z)`1 < E-bound L~z by Th51,XXREAL_0:2;
  then
A17: (N-min L~z)`1 < (E-min L~z)`1 by EUCLID:52;
A18: E-min L~z in rng z by Th45;
  then
A19: i1 in dom z by FINSEQ_4:20;
  then
A20: z/.i1 = z.i1 by PARTFUN1:def 6
    .= E-min L~z by A18,FINSEQ_4:19;
A21: i1 <= len z by A19,FINSEQ_3:25;
  z/.len z = N-min L~z by A1,FINSEQ_6:def 1;
  then
A22: i1 < len z by A21,A20,A17,XXREAL_0:1;
  then i1 + 1 <= len z by NAT_1:13;
  then len z - i1 >= 1 by XREAL_1:19;
  then len z -' i1 >= 1 by NAT_D:39;
  then
A23: len z -' i1 + 1 >= 1+1 by XREAL_1:6;
A24: i1 > i2 by A2,A8,A20,XXREAL_0:1;
  then i1 > 1 by A10,XXREAL_0:2;
  then reconsider M = mid(z,len z,i1) as S-Sequence_in_R2 by A22,Th37;
A25: len z in dom z by FINSEQ_5:6;
  then
A26: M/.len M = z/.i1 by A19,Th9
    .= E-min L~z by A18,FINSEQ_5:38;
  1 <= i1 by A19,FINSEQ_3:25;
  then
A27: len M = len z -' i1 + 1 by A21,FINSEQ_6:187;
A28: L~M misses L~h by A21,A24,A12,Th49;
A29: z/.1 = z/.len z by FINSEQ_6:def 1;
  then
A30: M/.1 = z/.1 by A19,A25,Th8;
  per cases;
  suppose that
A31: NW-corner L~z = N-min L~z;
    M/.1 = z/.len z by A19,A25,Th8;
    then
A32: (M/.1)`1 = W-bound L~z by A1,A29,A31,EUCLID:52;
    M is_in_the_area_of z & (M/.len M)`1 = E-bound L~z by A19,A25,A26,Th21,Th22
,EUCLID:52;
    then M is_a_h.c._for z by A32;
    hence contradiction by A16,A28,A27,A23,Th29;
  end;
  suppose
    NW-corner L~z <> N-min L~z;
    then reconsider
    g = <*NW-corner L~z*>^M as S-Sequence_in_R2 by A1,A19,A25,A29,Th66;
A33: len g >= 2 & L~g = L~M \/ LSeg(NW-corner L~z,M/.1) by SPPOL_2:20
,TOPREAL1:def 8;
    g/.1 = NW-corner L~z by FINSEQ_5:15;
    then
A34: (g/.1)`1 = W-bound L~z by EUCLID:52;
    LSeg(M/.1,NW-corner L~z) /\ L~h c= LSeg(M/.1,NW-corner L~z) /\ L~z by A10
,A7,A13,JORDAN4:35,XBOOLE_1:26;
    then
A35: LSeg(M/.1,NW-corner L~z) /\ L~h c= {M/.1} by A1,A30,PSCOMP_1:43;
    len M in dom M & len g = len M + len<*NW-corner L~z*> by FINSEQ_1:22
,FINSEQ_5:6;
    then g/.len g = M/.len M by FINSEQ_4:69
      .= z/.i1 by A19,A25,Th9
      .= E-min L~z by A18,FINSEQ_5:38;
    then
A36: (g/.len g)`1 = E-bound L~z by EUCLID:52;
A37: M/.1 in L~M by A27,A23,JORDAN3:1;
    M is_in_the_area_of z & <*NW-corner L~z*> is_in_the_area_of z by A19,A25
,Th21,Th22,Th26;
    then g is_in_the_area_of z by Th24;
    then g is_a_h.c._for z by A34,A36;
    hence contradiction by A16,A28,A33,A35,A37,Th29,ZFMISC_1:125;
  end;
end;
